Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

1088 / 13645 ﾂﾘｰ

←次へ　｜　前へ→

▼

【76375】［無題］ ペンネーム船長 14/11/9(日) 23:57

【76376】Re:［無題］ γ 14/11/10(月) 0:10

【76377】Re:［無題］ γ 14/11/10(月) 7:06

【76381】Re:［無題］ γ 14/11/11(火) 22:38

【76382】Re:［無題］ ペンネーム船長 14/11/12(水) 0:15

【76383】Re:［無題］ γ 14/11/12(水) 6:13

【76390】Re:［無題］ ペンネーム船長 14/11/14(金) 0:11


	【76375】［無題］

ペンネーム船長 - 14/11/9(日) 23:57 -


	引用なし

	パスワード

お世話になります。
『商品一覧表K（管理記号）.xls』というブックのシートに『商品1』があったとき、その行の先頭に○を付けるなど加工し、その行に太線を引きたいのですが、下記のところでエラーが出てしまいます。
先頭に○を付けたり数量に取り消し線を引いたり、数量を増減したりする事は正常に動くのですが、太線を引く事が出来ません。
間違いを教えてくれますでしょうか。
エラーは、実行時エラー1004/RangeクラスのSelectメソッドが失敗しました。です。
宜しくお願いします。

'状況：マクロのあるブックの他に『商品一覧表K（管理記号）.xls』というブックが立ち上がっています。
Private Sub CommandButton1_Click()

Dim buf As String
Dim wb As Workbook
Dim K As String '管理記号用変数
Dim sh As Worksheet
Dim obj As Range
Dim obj2 As Range
Dim w As String
Dim n As Integer
Dim n2 As Integer

K = ThisWorkbook.Worksheets("ツール").Range("B6").Value　'管理記号があるセル

Const path = "C:\Users\●○\Desktop\test\"
buf = Dir(path & "\*商品一覧表" & K & "*.xls")
Set wb = Workbooks.Open(path & buf)

For Each sh In Worksheets
　　　　　
　　Set obj = sh.Cells.Find(what:="商品1", LookIn:=xlValues, lookat:=xlWhole, MatchCase:=False, MatchByte:=False)　 '1回目の検索

　　If Not obj Is Nothing Then　'『商品1』があったとき
　　　　
　　　　w = obj.Offset(0, 7).Value　　 'Ｋ列（階数）
　　　　n = obj.Offset(0, 3).Value　　 'Ｇ列（数量）
　　　　obj.Offset(0, 4).Value = "▲" & n
　　　　obj.Offset(0, 5).Value = "0"
　　　　obj.Offset(0, -3).Value = "○"
　　　　obj.Offset(0, 3).Font.Strikethrough = True '取り消し線を引く
　　　　
　　　 '*****検索出来た行に太線を引きたい*****
　　　　sh.Range(obj.Offset(0, -3), obj.Offset(0, 10)).Select 'エラーが出る
　　　　With Selection.Borders(xlEdgeBottom)
　　　　　.LineStyle = xlContinuous
　　　　　.Weight = xlMedium
　　　　End With
　　
　　　　If w = "1" Then　'商品1が1階にあるとき
　　　　　　　　Set obj2 = sh.Cells.Find(what:="商品2", LookIn:=xlValues, lookat:=xlWhole, MatchCase:=False, MatchByte:=False)　'続けて2回目の検索
　　　　　　　　n2 = obj2.Offset(0, 3).Value　 'Ｇ列（数量）
　　　　　　　　obj2.Offset(0, 4).Value = "＋" & n
　　　　　　　　obj2.Offset(0, 5).Value = n2 + n
　　　　　　　　obj2.Offset(0, -3).Value = "○"
　　　　　　　　obj2.Offset(0, 3).Font.Strikethrough = True '取り消し線を引く
　　　　　　　　
　　　　　　　'*****検索出来た行に太線を引きたい*****
　　　　　　　 sh.Range(obj2.Offset(0, -3), obj2.Offset(0, 10)).Select　'エラーが出る
　　　　　　　　　 With Selection.Borders(xlEdgeBottom)
　　　　　　　　 .LineStyle = xlContinuous
　　　　　　　　 .Weight = xlMedium
　　　　　　　 End With
　　　　End If
　　　　
　　　　If w = "2" Or w = "3" Or w = "4" Or w = "5" Or w = "6" Then　'商品1が2階～6階にあるとき
　　　　　　　　Set obj2 = sh.Cells.Find(what:="商品3", LookIn:=xlValues, lookat:=xlWhole, MatchCase:=False, MatchByte:=False)　'続けて2回目の検索
　　　　　　　　n2 = obj2.Offset(0, 3).Value　 'Ｇ列（数量）
　　　　　　　　obj2.Offset(0, 4).Value = "＋" & n
　　　　　　　　obj2.Offset(0, 5).Value = n2 + n
　　　　　　　　obj2.Offset(0, -3).Value = "○"
　　　　　　　　obj2.Offset(0, 3).Font.Strikethrough = True '取り消し線を引く
　　　　　　
　　　　　　　 '*****検索出来た行に太線を引きたい*****
　　　　　　　　sh.Range(obj2.Offset(0, -3), obj2.Offset(0, 10)).Select　’エラーが出る　　　　　　　　　　　　　With Selection.Borders(xlEdgeBottom)
　　　　　　　　 .LineStyle = xlContinuous
　　　　　　　　 .Weight = xlMedium
　　　　　　　 End With
　　　　End If
　　End If
　　w = ""
　　n = 0
　　n2 = 0
Next sh

End Sub


	【76376】Re:［無題］

γ - 14/11/10(月) 0:10 -


	引用なし

	パスワード

全てを読んでいるわけではなく恐縮です。
sh.Range(obj.Offset(0, -3), obj.Offset(0, 10)).Select　'エラーが出る
objはどの列にあるかデバッグしましょう。
仮にA列とすると、左に３つ行ったところは？


	【76377】Re:［無題］

γ - 14/11/10(月) 7:06 -


	引用なし

	パスワード

> sh.Range(obj.Offset(0, -3), obj.Offset(0, 10)).Select 'エラーが出る
> With Selection.Borders(xlEdgeBottom)
> 　　.LineStyle = xlContinuous
> 　　.Weight = xlMedium
> End With
Selectは使わずに、↓のようにしては？
With sh.Range(obj.Offset(0, -3), obj.Offset(0, 10)).Borders(xlEdgeBottom)
　　.LineStyle = xlContinuous
　　.Weight = xlMedium
End With


	【76381】Re:［無題］

γ - 14/11/11(火) 22:38 -


	引用なし

	パスワード

商品2,商品3の有無チェックが必要かもしれないが、
一応、修正版を載せておきます。

Private Sub CommandButton1_Click()

　　Dim buf As String
　　Dim wb As Workbook
　　Dim K As String　　'管理記号用変数
　　Dim sh As Worksheet
　　Dim obj As Range
　　Dim obj2 As Range
　　Dim w As String
　　Dim n As Integer
　　Dim n2 As Integer

　　K = ThisWorkbook.Worksheets("ツール").Range("B6").Value　'管理記号があるセル

　　Const path = "C:\Users\●○\Desktop\test\"
　　buf = Dir(path & "\*商品一覧表" & K & "*.xls")
　　Set wb = Workbooks.Open(path & buf)

　　For Each sh In Worksheets
　　　　Set obj = sh.Cells.Find(what:="商品1", LookIn:=xlValues, _
　　　　　　　　　lookat:=xlWhole, MatchCase:=False, MatchByte:=False)　 '1回目の検索
　　　　If Not obj Is Nothing Then　'『商品1』があったとき
　　　　　　w = obj.Offset(0, 7).Value　　 'Ｋ列（階数）
　　　　　　n = obj.Offset(0, 3).Value　　 'Ｇ列（数量）
　　　　　　obj.Offset(0, 4).Value = "▲" & n
　　　　　　obj.Offset(0, 5).Value = "0"
　　　　　　obj.Offset(0, -3).Value = "○"
　　　　　　obj.Offset(0, 3).Font.Strikethrough = True　　'取り消し線を引く

　　　　　　'*****検索出来た行に太線を引きたい*****
　　　　　　With sh.Range(obj.Offset(0, -3), obj.Offset(0, 10)).Borders(xlEdgeBottom)
　　　　　　　　.LineStyle = xlContinuous
　　　　　　　　.Weight = xlMedium
　　　　　　End With

　　　　　　If w = "1" Then　'商品1が1階にあるとき
　　　　　　　　Set obj2 = sh.Cells.Find(what:="商品2", LookIn:=xlValues, _
　　　　　　　　　　lookat:=xlWhole, MatchCase:=False, MatchByte:=False)　'続けて2回目の検索
　　　　　　　　n2 = obj2.Offset(0, 3).Value　 'Ｇ列（数量）
　　　　　　　　obj2.Offset(0, 4).Value = "＋" & n
　　　　　　　　obj2.Offset(0, 5).Value = n2 + n
　　　　　　　　obj2.Offset(0, -3).Value = "○"
　　　　　　　　obj2.Offset(0, 3).Font.Strikethrough = True　　'取り消し線を引く

　　　　　　　　'*****検索出来た行に太線を引きたい*****
　　　　　　　　With sh.Range(obj2.Offset(0, -3), obj2.Offset(0, 10)).Borders(xlEdgeBottom)
　　　　　　　　　　.LineStyle = xlContinuous
　　　　　　　　　　.Weight = xlMedium
　　　　　　　　End With
　　　　　　End If

　　　　　　If w = "2" Or w = "3" Or w = "4" Or w = "5" Or w = "6" Then　
　　　　　　　　Set obj2 = sh.Cells.Find(what:="商品3", LookIn:=xlValues, _
　　　　　　　　　　lookat:=xlWhole, MatchCase:=False, MatchByte:=False)
　　　　　　　　n2 = obj2.Offset(0, 3).Value　 'Ｇ列（数量）
　　　　　　　　obj2.Offset(0, 4).Value = "＋" & n
　　　　　　　　obj2.Offset(0, 5).Value = n2 + n
　　　　　　　　obj2.Offset(0, -3).Value = "○"
　　　　　　　　obj2.Offset(0, 3).Font.Strikethrough = True　　'取り消し線を引く

　　　　　　　　'*****検索出来た行に太線を引きたい*****
　　　　　　　　With sh.Range(obj2.Offset(0, -3), obj2.Offset(0, 10)).Borders(xlEdgeBottom)
　　　　　　　　　　.LineStyle = xlContinuous
　　　　　　　　　　.Weight = xlMedium
　　　　　　　　End With
　　　　　　End If
　　　　End If
　　　　w = ""
　　　　n = 0
　　　　n2 = 0
　　Next sh
End Sub
繰り返しますが、シートが選択されていない状態で、セルを直接選択することは
できません。


	【76382】Re:［無題］

ペンネーム船長 - 14/11/12(水) 0:15 -


	引用なし

	パスワード

▼γ さん：
ご返事遅れてスミマセン。
今朝、前回のアドバイスに書き換えて会社で動かしてみたら、上手く罫線を引くことが出来ました。
ここに挙げたコードは一部だったので、商品1や商品2、商品3が無かったときの処置は他のところで処理しております。

>繰り返しますが、シートが選択されていない状態で、セルを直接選択することは
>できません。
このアドバイスが解決の鍵となりました。
でも、なぜ、始めの私のコードではシートをSelect出来なかったのでしょうか。
もし、宜しかったらこのあたりの説明をお願いします。


	【76383】Re:［無題］

γ - 14/11/12(水) 6:13 -


	引用なし

	パスワード

▼ペンネーム船長さん：
>でも、なぜ、始めの私のコードではシートをSelect出来なかったのでしょうか。
逆にお尋ねしますが、コードのどこでシートをSelectしていますか？

以下、想像で書きます。違っていたら失礼。
For Each sh In Worksheets
　　sh.Cells(1,1).Value = 1
Next
というコードがあったとき、
「人間がそれを手作業でやる」イメージを持たれていませんか？

まず、最初のシートを開いて、
そのA1セルに、1を入れる。
次に、2番目のシートを開いて・・・

人間がやるなら、シートを次々に開いていかないと、セルに入力できません。
しかし、それはとても無駄なわけです。
選択しなくても、
　　sh.Cells(1,1).Value = 1
で可能なんです。可能だし、そうすべきなんです。

しかも、うっかり
For Each sh In Worksheets
　　sh.Cells(1,1).Select
　　Selection.Value = 1
Next
と書いてしまったら、そこでアウト。ゲームセット。それはエラーになるのです。
理由はもうおわかりでしょう。

------------------------------------
「VBA高速化テクニック」
ht tp://officetanaka.net/excel/vba/speed/index.htm
のなかの
「無駄なSelectをしない」
ht tp://officetanaka.net/excel/vba/speed/s2.htm
を参考にして下さい。
「VBA高速化テクニック」も熟読されるとよいでしょう。

そこでは主として処理速度に重点を置いて書かれていますが、
可読性の向上の観点からも、「Selectするな」が推奨されます。

例外的な場合を除いて、Selectを使う必要はありません。
書いたらエラーになることが多い。
今回と、【76344】取り消し線が引けない(14/11/1(土) 21:29 )　
がその例です。
百害あって一利なし、です。

ベテランさんのようにお見受けしますので、
Selectを簡単に使ってしまう癖から、
早く卒業していただきたいと思います。

# 失礼がありましたら、お許し願います。


	【76390】Re:［無題］

ペンネーム船長 - 14/11/14(金) 0:11 -


	引用なし

	パスワード

γさん
ご丁寧な解説有難う御座います。
今回も取り消し線のときも、マクロの記録に頼っていたのが誤りの原因でした。
Selectすると実行速度が遅くなることは知っていましたが、万能で使えるという変な思い込みをしていました。Selectした方が確実に実態を掴んだような間違った安心感から抜けていませんでした。正に>「人間がそれを手作業でやる」イメージそのものでした。ご紹介していただいたＶＢＡ解説ＨＰでもSelectは出来るだけ使うのを止めましょうとありましたね。これを機会にSelectから卒業したいと思います。
ＶＢＡとは長い間付き合っていますが、基本の知識が抜けているようで、なかなかスラスラと行きません。大学時代コンピューターの授業は大の苦手だったのですが、会社の仕事でどうしてもＶＢＡの知識が必要になり、本の事例を写しながらやってきました。ある程度やると面白味が分り、それ以来独学で見様見まねでやってきました。まだまだ続けてゆきたいと思っています。稚拙な質問があるかも知れませんが宜しくお願いします。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

1088 / 13645 ﾂﾘｰ

←次へ　｜　前へ→

ページ：

┃

記事番号：

(SS)C-BOARD v3.8 is Free