Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちら をご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。

  新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム  
6718 / 13644 ﾂﾘｰ ←次へ　｜　前へ→
▼ 【43548】シートのコピーについて りこ 06/10/19(木) 10:04 質問[未読]
【43551】Re:シートのコピーについて へっぽこ 06/10/19(木) 10:28 回答[未読]
【43553】Re:シートのコピーについて りこ 06/10/19(木) 10:35 お礼[未読]
【43557】Re:シートのコピーについて Jaka 06/10/19(木) 11:02 発言[未読]
【43548】シートのコピーについて
質問  りこ  - 06/10/19(木) 10:04 -
引用なし
パスワード
   すみません。どなたか教えてください。行き詰っております。
現在、既存のファイル（１０月）にコードを書き込んでおります。
コードは下記の通り


Sub Test3()
　 Dim myf As Variant
　 Dim MyB As Workbook
　 Dim i As Integer, bcnt As Integer, SCnt As Integer
　 Dim fname As Worksheet　

　 With Application
　　　myf = .GetOpenFilename("エクセルブック(*.xls),*.xls", , , , True)
　　　If VarType(myf) = 11 Then Exit Sub
　　　bcnt = UBound(myf)
　　　SCnt = .SheetsInNewWorkbook
　　　.SheetsInNewWorkbook = bcnt
　　　.ScreenUpdating = False　　　
　 End With
　 Set MyB = Workbooks.Add
　 For i = 1 To bcnt
　　　Workbooks.Open myf(i)
　　　ActiveWorkbook.Worksheets(3) _
　　　.Cells.Copy MyB.Worksheets(i).Range("A1")
　　　ActiveWorkbook.Close False　　
　 Next i
　 With Application
　　　.SheetsInNewWorkbook = SCnt
　　　.ScreenUpdating = True
　 End With

　
　 Set MyB = Nothing
End Sub

Worksheets(3)の全てのシートをコピーし、新しいブックに貼り付けるというコードです。
この「Worksheets(3)」を「"内訳書*"」という風にワイルドカードを使って参照したいのです。If文を使用したり、名前を定義したりしてみたんですが、いまひとつ
うまくいきません。
どなたかご回答をお願いいたします。 <(＿ ＿)>
【43551】Re:シートのコピーについて
回答  へっぽこ  - 06/10/19(木) 10:28 -
引用なし
パスワード
   こんにちは。

Sub Test3()
　 Dim myf As Variant
　 Dim MyB As Workbook
　 Dim i As Integer, bcnt As Integer, SCnt As Integer
　 Dim sNo As Integer '対象シート番号
　 Dim fname As Worksheet

　 With Application
　　　myf = .GetOpenFilename("エクセルブック(*.xls),*.xls", , , , True)
　　　If VarType(myf) = 11 Then Exit Sub
　　　bcnt = UBound(myf)
　　　SCnt = .SheetsInNewWorkbook
　　　.SheetsInNewWorkbook = bcnt
　　　.ScreenUpdating = False
　 End With
　 Set MyB = Workbooks.Add
　 For i = 1 To bcnt
　　　Workbooks.Open myf(i)
　　　'いま開いたブックのシートを見て回る
　　　For sNo = 1 To Worksheets.Count
　　　　'Like演算子で比較
　　　　If Worksheets(sNo).Name Like "内訳書*" Then
　　　　　　Exit For
　　　　End If
　　　Next
　　　If sNo <= Worksheets.Count Then
　　　　'見つかった場合
　　　　ActiveWorkbook.Worksheets(sNo) _
　　　　　　.Cells.Copy MyB.Worksheets(i).Range("A1")
　　　End If
　　　ActiveWorkbook.Close False
　 Next i
　 With Application
　　　.SheetsInNewWorkbook = SCnt
　　　.ScreenUpdating = True
　 End With
　
　 Set MyB = Nothing
End Sub

こんな感じでどうでしょうか？
【43553】Re:シートのコピーについて
お礼  りこ  - 06/10/19(木) 10:35 -
引用なし
パスワード
   へっぽこ さん：
どうもありがとうございました。
解決です＾＾
【43557】Re:シートのコピーについて
発言  Jaka  - 06/10/19(木) 11:02 -
引用なし
パスワード
   検証してないので、動かなかったらごめんなさい。

Sub Test3()
　 Dim myf As Variant
　 Dim MyB As Workbook, OpWB As Workbook, WS As Worksheet
　 Dim i As Integer, bcnt As Integer, SCnt As Integer
　 Dim fname As Worksheet

　 With Application
　　　myf = .GetOpenFilename("エクセルブック(*.xls),*.xls", , , , True)
　　　If VarType(myf) = 11 Then Exit Sub
　 End With
　 Ct = 0
　 For Each st In myf
　　　 Set OpWB = Workbooks.Open(st)
　　　 For Each WS In OpWB.Sheets
　　　　　 If WS.Name Like "内訳書*" Then
　　　　　　　If MyB.Sheets.Count <= Ct Then
　　　　　　　　 MyB.Worksheets.Add after:=Worksheets(MyB.Worksheets.Count)
　　　　　　　End If
　　　　　　　Ct = Ct + 1
　　　　　　　WS.UsedRange.Copy MyB.Sheets(Ct).Range(WS.UsedRange.Address)
　　　　　　　DoEvents
　　　　　 End If
　　　 Next
　　　 OpWB.Close (False)
　　　 Set OpWB = Nothing
　 Next
　
　 With Application
　　　.ScreenUpdating = True
　 End With
　
　 Set MyB = Nothing
End Sub
  新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム  
6718 / 13644 ﾂﾘｰ ←次へ　｜　前へ→
ページ：  ┃  記事番号：
2610219
(SS)C-BOARD v3.8 is Free