Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちら をご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。

  新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム  
7260 / 13645 ﾂﾘｰ ←次へ　｜　前へ→
▼ 【40136】フォルダ内のファイル読み込み みぽりん 06/7/7(金) 13:47 質問[未読]
【40140】Re:フォルダ内のファイル読み込み ちくたく 06/7/7(金) 14:09 回答[未読]
【40147】Re:フォルダ内のファイル読み込み みぽりん 06/7/7(金) 15:22 質問[未読]
【40141】Re:フォルダ内のファイル読み込み ひげくま 06/7/7(金) 14:12 発言[未読]
【40143】Re:フォルダ内のファイル読み込み ハチ 06/7/7(金) 14:57 回答[未読]
【40152】Re:フォルダ内のファイル読み込み みぽりん 06/7/7(金) 15:59 質問[未読]
【40157】Re:フォルダ内のファイル読み込み ハチ 06/7/7(金) 16:39 発言[未読]
【40263】Re:フォルダ内のファイル読み込み みぽりん 06/7/10(月) 11:45 質問[未読]
【40162】Re:フォルダ内のファイル読み込み Kein 06/7/7(金) 17:34 回答[未読]
【40238】Re:フォルダ内のファイル読み込み みぽりん 06/7/10(月) 9:54 質問[未読]
【40242】Re:フォルダ内のファイル読み込み Blue 06/7/10(月) 10:01 回答[未読]
【40243】Re:フォルダ内のファイル読み込み かみちゃん 06/7/10(月) 10:04 発言[未読]
【40250】Re:フォルダ内のファイル読み込み みぽりん 06/7/10(月) 10:34 お礼[未読]
【40255】Re:フォルダ内のファイル読み込み みぽりん 06/7/10(月) 10:55 質問[未読]
【40258】Re:フォルダ内のファイル読み込み みぽりん 06/7/10(月) 11:14 お礼[未読]
【40260】度々すみませんが、教えてください。 みぽりん 06/7/10(月) 11:37 質問[未読]
【40262】Re:度々すみませんが、教えてください。 Blue 06/7/10(月) 11:43 回答[未読]
【40276】Re:度々すみませんが、教えてください。 みぽりん 06/7/10(月) 15:17 お礼[未読]
【40136】フォルダ内のファイル読み込み
質問  みぽりん  - 06/7/7(金) 13:47 -
引用なし
パスワード
   こんにちは。ヘルプを見ても意味があまりよくわからないほどの
レベルです。宜しくお願いいたします。

フォルダ内にBNDファイルというファイルが120くらいあって、（CSVファイルって言うんでしょうか？テキストファイルとして読み込めます。）１つのファイルを読み込むと、A1からE16までデータが入っています。このデータを

ファイル1　C7 C9 C8 C13 C15 C14　
ファイル2　C7 C9 C8 C13 C15 C14　
ファイル3　C7 C9 C8 C13 C15 C14
・・・・
ファイル120

という風に表にしたいと思っています。
質問箱の過去のものを検索して私でもなんとか内容が理解できるものが、以下の
記事でした。1行だけ読み込むマクロなので、私がやりたいこととは
違うのですが、ここまでは実際に試してできました。

[#25953]
Option Explicit
Sub Macro1()
　Dim MyPath As String
　Dim MyName As String
　Dim OpenFileName As String
　Dim n As Long
　Dim buf As Variant
　Dim tmp As String
　Dim RowNo As Long

　MyPath = ThisWorkbook.Path ' CSVのフォルダ名の指定
　MyName = Dir(MyPath & "\*.csv") 'CSVファイルすべて
　RowNo = 1
　Do While MyName <> ""　　' ループを開始します。
　　'元のCSVファイル名のフルパス
　　OpenFileName = MyPath & "\" & MyName
　　
　　'変更したファイルをテキストモードで開く
　　n = FreeFile
　　Open OpenFileName For Input As #n
　　'最初の1行を読み込む
　　Line Input #n, tmp
　　Close #n
　　'カンマごとに区切る
　　buf = Split(tmp, ",")
　　'Ax:Dx（xは行番号）セルに書き込む
　　Range("A" & RowNo & ":D" & RowNo) = buf
　　'行番号をカウントアップ
　　RowNo = RowNo + 1
　　'次のファイルを探す
　　MyName = Dir
　Loop
　MsgBox "終了"
End Sub

　この後、どう変更すればよいのかよくわかりません。
1行ではなくて16行ある場合はどうしたらよいのか。
そのうち必要なデータのみ抽出するにはどうしたらよいのか。
初歩的な質問で大変申し訳ありませんが、教えていただけないでしょうか？
宜しくお願いいたします。
【40140】Re:フォルダ内のファイル読み込み
回答  ちくたく  - 06/7/7(金) 14:09 -
引用なし
パスワード
   みぽりん さん
こんにちは。
bndという拡張子がよくわからないのと、
先ほどのコードを活かした内容ではないですが、
これでいきませんかね?
(bndという拡張子ではダメかもしれません)

昔、自分のためにつくったやつの焼き直しなので、細かく見てません。
ちょっと、忙しいので、クレーム対応遅れるかもしれません。
失礼致します。

Sub データ書き写し()

　　Dim myFo As String
　　Dim fileStr As String
　　Dim myWs As Worksheet, myWb As Workbook
　　Dim dataWb As Workbook
　　Dim i As Integer
　　
　　Set myWb = Workbooks.Add
　　Set myWs = myWb.ActiveSheet
　　
　　myFo = "D:\Ki"　 'フォルダのパス
　　fileStr = Dir(myFo & "\", vbNormal)
　　i = 1
　　
　　Do While fileStr <> ""
　　　　Set dataWb = Workbooks.Open(myFo & "\" & fileStr)
　　　　With dataWb.ActiveSheet
　　　　　　myWs.Range("A" & i).Value = "ファイル" & i
　　　　　　myWs.Range("B" & i).Value = .Range("C7").Value
　　　　　　myWs.Range("C" & i).Value = .Range("C9").Value
　　　　　　myWs.Range("D" & i).Value = .Range("C8").Value
　　　　　　myWs.Range("E" & i).Value = .Range("C13").Value
　　　　　　myWs.Range("F" & i).Value = .Range("C15").Value
　　　　　　myWs.Range("G" & i).Value = .Range("C14").Value
　　　　End With
　　　　i = i + 1
　　　　dataWb.Close
　　　　fileStr = Dir
　　Loop
　　
End Sub
【40141】Re:フォルダ内のファイル読み込み
発言  ひげくま  - 06/7/7(金) 14:12 -
引用なし
パスワード
   ファイルの読み込み方が違うので、こういうやり方もある、という程度に読んでください。

　　Dim TS As Object
　　Dim FileName As String
　　Dim LineData As String

　　'ファイル内容を取り込む
　　FileName = "xxxxxxxx.xxx"
　　Set TS = CreateObject("Scripting.FileSystemObject").OpenTextFile(FileName)

　　'ファイル内容(テキストストリーム)の最後までループ
　　Do Until TS.AtEndOfStream
　　　　'1行を読み込む
　　　　LineData = TS.ReadLine

　　　　'1行ごとの処理

　　Loop

　　Set TS = Nothing

これは1つのファイルに関しての処理なので、複数のファイルを処理する場合は、それなりに、工夫してください。

また、必要なデータの抽出に関しては、条件が解らないので、何ともアドバイスできません。
【40143】Re:フォルダ内のファイル読み込み
回答  ハチ  - 06/7/7(金) 14:57 -
引用なし
パスワード
   自分はこんな感じのを使ってます。
このファイルのあるフォルダに"Sub"フォルダを作成して
その中に処理したいファイルを入れてください。
取り出し条件は、
Private Function Fg_Chkの
Caseを変更してみてください。

Option Explicit

Sub Text_In()

Dim dat As String
Dim buf() As String
Dim i As Long
Dim Fg As Boolean
Dim MyPath, MyFile As String

ActiveSheet.Cells.ClearContents
Application.ScreenUpdating = False
　　
MyPath = ThisWorkbook.Path & "\Sub\"
MyFile = Dir(MyPath & "*")

i = 1
Do Until MyFile = ""
　　Open MyPath & MyFile For Input As #1
　　Do Until EOF(1)
　　　　Line Input #1, dat
　　　　Fg = Fg_Chk(dat)
　　　　If Fg = True Then
　　　　　　buf = Split(dat, ",")
　　　　　　With ActiveSheet
　　　　　　　　.Range(.Cells(i, 1), .Cells(i, UBound(buf) + 1)).Value = buf
　　　　　　End With
　　　　　　i = i + 1
　　　　End If
　　Loop
　　Close #1
　　
　　MyFile = Dir()
Loop
Application.ScreenUpdating = True

End Sub


Private Function Fg_Chk(dat As String) As Boolean

Select Case True
　　Case dat Like "*AA*"
　　　　Fg_Chk = True
　　Case dat Like "*担当者*"
　　　　Fg_Chk = True
　　Case dat Like "2006/07/07*"
　　　　Fg_Chk = True
　　Case Else
　　　　Fg_Chk = False
End Select

End Function
【40147】Re:フォルダ内のファイル読み込み
質問  みぽりん  - 06/7/7(金) 15:22 -
引用なし
パスワード
   ちくたく さん：

お返事ありがとうございました。
教えていただいたマクロを実行してみたところ、
ファイル名だけは表示されますが、
データは表示されませんでした。たぶん、
bndファイルという形式のせいでしょうか。bndというファイルは
テキストモードでスペース区切りでエクセルで開くことが
できます。ちなみに、質問で参考にしたマクロでは、
1行目のデータは読み込まれました。
テキスト形式で読み込むところをマクロの記録をすると、

Sub Macro1()

Workbooks.OpenText Filename:= ファイル名　, Origin :=932, startRow:=1,　　　 DataType:=xlDelimited, TextQualifier:=xlDoubleQuote　, ConsecutiveDelimiter:=True, Tab:=False, Semicolon:=False, Comma:=False,　　 Space:=True, Other:=False, FieldInfo:=Array(Array(1,1), Array(2, 1)) , TrailingMinusNumbers:=True

End sub

となりました。エクセルのファイルではないので、ファイルをopenする時に
テキストで開くような記述が必要だと思うのですが・・・。
1行1行読み込むようにした方がよいのでしょうか？
【40152】Re:フォルダ内のファイル読み込み
質問  みぽりん  - 06/7/7(金) 15:59 -
引用なし
パスワード
   ハチさん、お返事どうもありがとうございます。

初歩的な質問で大変恐縮ですが、
Private Function Fg_Chk 以下について教えてください。
このCase文はループの中に入っていないですよね？入ってるんですか？
1件のファイルを読み込んだ時に、C7 C9 C8 C13 C15 C14　の情報だけ
欲しいのですが、datに入れちゃっていいんですか？
（すみません。意味がよくわかってません。）
True Falseで返す意味がわかりません。お手数をおかけいたしますが、
もうちょっと説明していただけませんか？
【40157】Re:フォルダ内のファイル読み込み
発言  ハチ  - 06/7/7(金) 16:39 -
引用なし
パスワード
   ▼みぽりん さん：

>Private Function Fg_Chk 以下について教えてください。
>このCase文はループの中に入っていないですよね？入ってるんですか？

入ってます。
>Line Input #1, dat
>Fg = Fg_Chk(dat)
ここでFg_Chkファンクションを呼び出して
結果をFgに入れています。
1行分をdatに読み込み→チェック→Trueなら書き込み　としてます。
ステップ実行すると、Loopの中でFunctionに飛んでいるのが確認できると思います。

>1件のファイルを読み込んだ時に、C7 C9 C8 C13 C15 C14　の情報だけ
>欲しいのですが、datに入れちゃっていいんですか？

ここの部分の意味がわかりません。
これは、テキストをExcelで開いた場合のセルのアドレスですか？？
テキストファイルの"7行目の3列目のデータ"ということ？
それともテキストの内容ですか？
該当するアドレスだとすると、
>　　Do Until EOF(1)
>　　　　Line Input #1, dat
・
・
>　　　　End If
>　　Loop
Do〜Loopの間のロジックを変更するほうが効率が良いと思います。

テキストファイルの内容をUPしてみてください。
もちろん、見せられないデータは違う文字列に置き換えて。

>True Falseで返す意味がわかりません。お手数をおかけいたしますが、
>もうちょっと説明していただけませんか？

SubとFunctionで変数名が重複していてすいません＞＜
>Select Case True
>　　Case dat Like "*AA*"
dat Like "*AA*"の結果がTureならば、
Fg_Chkの戻り値がTureになる=FgがTureになる
わかりずらい・・・ですね・・
ここに一行を判定する条件を書けば良い　ということです。
【40162】Re:フォルダ内のファイル読み込み
回答  Kein  - 06/7/7(金) 17:34 -
引用なし
パスワード
   Sub Read_MyText()
　 Dim i As Long, j As Long
　 Dim MyAry, MyAry2
　 Dim Ary1, Ary2, Ary3
　 Dim Ary4, Ary5, Ary6
　 Dim FSO As Object
　 Dim MyF As String
　 Const MyFol As String = _
　 "C:\Documents and Settings\User\My Documents\"
　 '↑正確な保存先フォルダーのパスに変更する
　
　 MyF = Dir(MyFol & ".BND")
　 '↑ファイルが見つからないというMsgが出たら小文字の bnd に変えてみる
　 If MyF = "" Then
　　　MsgBox "拡張子が BND のファイルは見つかりません", 48
　　　Exit Sub
　 End If
　 Cells.ClearContents
　 Set FSO = CreateObject("Scripting.FileSystemObject")
　 Do
　　　With FSO.OpenTextFile(MyF, 1)
　　　　 For i = 1 To 6
　　　　　　.SkipLine
　　　　 Next i
　　　　 Ary1 = Split(.ReadLine, " ")(2)
　　　　 Ary2 = Split(.ReadLine, " ")(2)
　　　　 Ary3 = Split(.ReadLine, " ")(2)
　　　　 MyAry = Array(Ary1, Ary3, Ary2)
　　　　 For i = 1 To 3
　　　　　　.SkipLine
　　　　 Next i
　　　　 Ary4 = Split(.ReadLine, " ")(2)
　　　　 Ary5 = Split(.ReadLine, " ")(2)
　　　　 Ary6 = Split(.ReadLine, " ")(2)
　　　　 MyAry2 = Array(Ary4, Ary6, Ary5)
　　　　 j = j + 1
　　　　 With Cells(j, 1)
　　　　　　.Resize(, 3).Value = MyAry
　　　　　　.Offset(, 3).Resize(, 3).Value = MyAry2
　　　　 End With
　　　　 Erase MyAry, MyAry2
　　　　 .Close
　　　End With
　　　MyF = Dir()
　 Loop Until MyF = ""
　 Set FSO = Nothing
End Sub

で、どうでしょーか ? 空白シートを開いて試してみて下さい。
【40238】Re:フォルダ内のファイル読み込み
質問  みぽりん  - 06/7/10(月) 9:54 -
引用なし
パスワード
   Kein さん：

ご丁寧に説明も加えて教えてくださり、ありがとうございます。
.BNDというところを大文字にしても小文字にしても
ファイルは見つかりませんというメッセージが出ます。
（フォルダ内のファイルを見ると拡張子は.BNDになっているのに。）
どうしたらよいでしょうか？

>Sub Read_MyText()
>　 Dim i As Long, j As Long
>　 Dim MyAry, MyAry2
>　 Dim Ary1, Ary2, Ary3
>　 Dim Ary4, Ary5, Ary6
>　 Dim FSO As Object
>　 Dim MyF As String
>　 Const MyFol As String = _
>　 "C:\Documents and Settings\User\My Documents\"
>　 '↑正確な保存先フォルダーのパスに変更する
>　
>　 MyF = Dir(MyFol & ".BND")
>　 '↑ファイルが見つからないというMsgが出たら小文字の bnd に変えてみる
>　 If MyF = "" Then
>　　　MsgBox "拡張子が BND のファイルは見つかりません", 48
>　　　Exit Sub
>　 End If
>　 Cells.ClearContents
>　 Set FSO = CreateObject("Scripting.FileSystemObject")
>　 Do
>　　　With FSO.OpenTextFile(MyF, 1)
>　　　　 For i = 1 To 6
>　　　　　　.SkipLine
>　　　　 Next i
>　　　　 Ary1 = Split(.ReadLine, " ")(2)
>　　　　 Ary2 = Split(.ReadLine, " ")(2)
>　　　　 Ary3 = Split(.ReadLine, " ")(2)
>　　　　 MyAry = Array(Ary1, Ary3, Ary2)
>　　　　 For i = 1 To 3
>　　　　　　.SkipLine
>　　　　 Next i
>　　　　 Ary4 = Split(.ReadLine, " ")(2)
>　　　　 Ary5 = Split(.ReadLine, " ")(2)
>　　　　 Ary6 = Split(.ReadLine, " ")(2)
>　　　　 MyAry2 = Array(Ary4, Ary6, Ary5)
>　　　　 j = j + 1
>　　　　 With Cells(j, 1)
>　　　　　　.Resize(, 3).Value = MyAry
>　　　　　　.Offset(, 3).Resize(, 3).Value = MyAry2
>　　　　 End With
>　　　　 Erase MyAry, MyAry2
>　　　　 .Close
>　　　End With
>　　　MyF = Dir()
>　 Loop Until MyF = ""
>　 Set FSO = Nothing
>End Sub
>
>で、どうでしょーか ? 空白シートを開いて試してみて下さい。
【40242】Re:フォルダ内のファイル読み込み
回答  Blue  - 06/7/10(月) 10:01 -
引用なし
パスワード
   > MyF = Dir(MyFol & ".BND")
には * が必要なのではないでしょうか？

MyF = Dir(MyFol & "*.BND")
【40243】Re:フォルダ内のファイル読み込み
発言  かみちゃん  - 06/7/10(月) 10:04 -
引用なし
パスワード
   こんにちは。かみちゃん　です。

>.BNDというところを大文字にしても小文字にしても
>ファイルは見つかりませんというメッセージが出ます。
>（フォルダ内のファイルを見ると拡張子は.BNDになっているのに。）

もしかして、
　MyF = Dir(MyFol & ".BND")
は、
　MyF = Dir(MyFol & "*.BND")
ではないでしょうか？
【40250】Re:フォルダ内のファイル読み込み
お礼  みぽりん  - 06/7/10(月) 10:34 -
引用なし
パスワード
   教えてくださった皆様

　MyF = Dir(MyFol & "*.BND")

でできました！そっか。*を入れないとただの.BNDファイルがフォルダ内に
存在していないからエラーメッセージが出たんですね。
今日中に表を作らなければいけないので、とてもとても助かりました。
教えていただいただけでもいろいろな記述方法があって、
時間がある時に、教えていただいた方法それぞれでできるように
頑張ってマクロを作って勉強してみます。
職場でマクロのできる人がいないので、皆さんのお陰で助かりました。
どうもありがとうございました。
【40255】Re:フォルダ内のファイル読み込み
質問  みぽりん  - 06/7/10(月) 10:55 -
引用なし
パスワード
   度々すみません！

一度目テストデータ10件だけでマクロを実行したらできたのですが、
2度目から、Do〜Loopの中の
With FSO.OpenTextFile(MyF, 1)
というところで、データがありませんというエラーメッセージが出て、
できなくなってしまいました。どうしてでしょうか？

>Sub Read_MyText()
>　 Dim i As Long, j As Long
>　 Dim MyAry, MyAry2
>　 Dim Ary1, Ary2, Ary3
>　 Dim Ary4, Ary5, Ary6
>　 Dim FSO As Object
>　 Dim MyF As String
>　 Const MyFol As String = _
>　 "C:\Documents and Settings\User\My Documents\"
>　 '↑正確な保存先フォルダーのパスに変更する
>　
>　 MyF = Dir(MyFol & "*.BND")
>　 '↑ファイルが見つからないというMsgが出たら小文字の bnd に変えてみる
>　 If MyF = "" Then
>　　　MsgBox "拡張子が BND のファイルは見つかりません", 48
>　　　Exit Sub
>　 End If
>　 Cells.ClearContents
>　 Set FSO = CreateObject("Scripting.FileSystemObject")
>　 Do
>　　　With FSO.OpenTextFile(MyF, 1)
>　　　　 For i = 1 To 6
>　　　　　　.SkipLine
>　　　　 Next i
>　　　　 Ary1 = Split(.ReadLine, " ")(2)
>　　　　 Ary2 = Split(.ReadLine, " ")(2)
>　　　　 Ary3 = Split(.ReadLine, " ")(2)
>　　　　 MyAry = Array(Ary1, Ary3, Ary2)
>　　　　 For i = 1 To 3
>　　　　　　.SkipLine
>　　　　 Next i
>　　　　 Ary4 = Split(.ReadLine, " ")(2)
>　　　　 Ary5 = Split(.ReadLine, " ")(2)
>　　　　 Ary6 = Split(.ReadLine, " ")(2)
>　　　　 MyAry2 = Array(Ary4, Ary6, Ary5)
>　　　　 j = j + 1
>　　　　 With Cells(j, 1)
>　　　　　　.Resize(, 3).Value = MyAry
>　　　　　　.Offset(, 3).Resize(, 3).Value = MyAry2
>　　　　 End With
>　　　　 Erase MyAry, MyAry2
>　　　　 .Close
>　　　End With
>　　　MyF = Dir()
>　 Loop Until MyF = ""
>　 Set FSO = Nothing
>End Sub
>
>で、どうでしょーか ? 空白シートを開いて試してみて下さい。
【40258】Re:フォルダ内のファイル読み込み
お礼  みぽりん  - 06/7/10(月) 11:14 -
引用なし
パスワード
   すみません。元データが間違っていました。
ごめんなさい。
【40260】度々すみませんが、教えてください。
質問  みぽりん  - 06/7/10(月) 11:37 -
引用なし
パスワード
   さきほどは、違うモジュールにマクロを書き直して1度目の実行だったので
できたのですが、やはり2度目以降は、
With FSO.OpenTextFile(MyF, 1)
のところで、ファイルがありませんというメッセージが出てできなくなります。
フォルダにファイルがあるのにどうしてでしょうか？

>>Sub Read_MyText()
>>　 Dim i As Long, j As Long
>>　 Dim MyAry, MyAry2
>>　 Dim Ary1, Ary2, Ary3
>>　 Dim Ary4, Ary5, Ary6
>>　 Dim FSO As Object
>>　 Dim MyF As String
>>　 Const MyFol As String = _
>>　 "C:\Documents and Settings\User\My Documents\"
>>　 '↑正確な保存先フォルダーのパスに変更する
>>　
>>　 MyF = Dir(MyFol & "*.BND")
>>　 '↑ファイルが見つからないというMsgが出たら小文字の bnd に変えてみる
>>　 If MyF = "" Then
>>　　　MsgBox "拡張子が BND のファイルは見つかりません", 48
>>　　　Exit Sub
>>　 End If
>>　 Cells.ClearContents
>>　 Set FSO = CreateObject("Scripting.FileSystemObject")
>>　 Do
>>　　　With FSO.OpenTextFile(MyF, 1)
>>　　　　 For i = 1 To 6
>>　　　　　　.SkipLine
>>　　　　 Next i
>>　　　　 Ary1 = Split(.ReadLine, " ")(2)
>>　　　　 Ary2 = Split(.ReadLine, " ")(2)
>>　　　　 Ary3 = Split(.ReadLine, " ")(2)
>>　　　　 MyAry = Array(Ary1, Ary3, Ary2)
>>　　　　 For i = 1 To 3
>>　　　　　　.SkipLine
>>　　　　 Next i
>>　　　　 Ary4 = Split(.ReadLine, " ")(2)
>>　　　　 Ary5 = Split(.ReadLine, " ")(2)
>>　　　　 Ary6 = Split(.ReadLine, " ")(2)
>>　　　　 MyAry2 = Array(Ary4, Ary6, Ary5)
>>　　　　 j = j + 1
>>　　　　 With Cells(j, 1)
>>　　　　　　.Resize(, 3).Value = MyAry
>>　　　　　　.Offset(, 3).Resize(, 3).Value = MyAry2
>>　　　　 End With
>>　　　　 Erase MyAry, MyAry2
>>　　　　 .Close
>>　　　End With
>>　　　MyF = Dir()
>>　 Loop Until MyF = ""
>>　 Set FSO = Nothing
>>End Sub
【40262】Re:度々すみませんが、教えてください。
回答  Blue  - 06/7/10(月) 11:43 -
引用なし
パスワード
   こういうときは、MsgBoxとかで確認するのが常套手段です。

　 Do
　　　MsgBox MyF ' MyFの文字列を表示
　　　With FSO.OpenTextFile(MyF, 1)

おそらく、
> MyF = Dir(MyFol & "*.BND")
の戻り値が、フルパスではなくファイル名だけになっているため、
パスが通っていないところにあるファイルが開けないようになってしまったのでしょう。

MyFol を使ってフルパスに文字列を変更してあげれば動くと思います。

With FSO.OpenTextFile(MyFol & MyF, 1)
【40263】Re:フォルダ内のファイル読み込み
質問  みぽりん  - 06/7/10(月) 11:45 -
引用なし
パスワード
   ▼ハチ さん：

>テキストファイルの内容をUPしてみてください。
>もちろん、見せられないデータは違う文字列に置き換えて。

ファイルはテキストとして読み込むと以下のような感じです。
スペース区切りで読み込むと、7行目の1354.34というデータがC7
の場所にあります。（わかりにくい説明ですみません。）


＜データ例＞
SpectralBands　　　　　　　　　　　　　　　　
2　　　　2　　　　　　　　　　　　
1354.34　　　　　　　　　　　　　　　　
1583.8　　　　　　　　　　　　　　　　
0　　　　4　　　　1　　　　　　　　
a*(g*gauss(1.41421*(x-p)/w)+(1-g)*loren((x-p)/w))　　　　　　　　　　　　
p　　　　0　　　　1354.34　　　　1102.16　　　　1602.47
a　　　　0　　　　51.9138　　　　0　　　　129.768
w　　　　0　　　　31.683　　　　1.00061　　　　500.305
g　　　　0　　　　0.773395　　　　0　　　　1
1　　　　4　　　　1　　　　　　　　
a*(g*gauss(1.41421*(x-p)/w)+(1-g)*loren((x-p)/w))　　　　　　　　　　　　
p　　　　0　　　　1583.8　　　　1332.9　　　　1833.2
a　　　　0　　　　128.724　　　　0　　　　129.768
w　　　　0　　　　22.8879　　　　1.00061　　　　500.305
g　　　　0　　　　0　　　　0　　　　1


これを、
ファイル１ 1354.34 31.683 51.9138 1583.8 22.8879 128.724
ファイル２・・・・

という表にしたいのです。
宜しくお願いいたします。
【40276】Re:度々すみませんが、教えてください。
お礼  みぽりん  - 06/7/10(月) 15:17 -
引用なし
パスワード
   ▼Blue さん：

Blueさんのおっしゃる通りにMsgBoxで確認したところ、
ファイル名だけになっていました。
フルパスに変更してみたらできました。
基本的なことですみませんでした。
ありがとうございました。
  新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム  
7260 / 13645 ﾂﾘｰ ←次へ　｜　前へ→
ページ：  ┃  記事番号：
2610219
(SS)C-BOARD v3.8 is Free