Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちら をご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。

  新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム  
9708 / 13657 ﾂﾘｰ ←次へ　｜　前へ→
▼ 【25952】複数csvファイルの読込み ひろし 05/6/19(日) 21:33 質問[未読]
【25953】Re:複数csvファイルの読込み かみちゃん 05/6/19(日) 22:12 回答[未読]
【25956】Re:複数csvファイルの読込み ひろし 05/6/20(月) 0:40 お礼[未読]
【25952】複数csvファイルの読込み
質問  ひろし  - 05/6/19(日) 21:33 -
引用なし
パスワード
   はじめまして

質問させて頂きます．
あるフォルダに，複数のcsvファイルが入っています．
以下の様にしたいと考えていますが，まったくの素人ですので，
アイデアがありません．ご協力をお願い致します．
※csvファイルは，1行で構成されている（内容も同じ順）
※最終的には，全csvを1シートにしたい

0618.csv
0001,○,いいえ,55

0620.csv
0010,○,はい,48

0621.csv
0002,×,いいえ,88

↓

Excelファイル（1シートに：カンマ区切り→各セルに）

0618　0001　○　いいえ　55
0620　0010　○　はい　　48
0621　0002　×　いいえ　88
【25953】Re:複数csvファイルの読込み
回答  かみちゃん  - 05/6/19(日) 22:12 -
引用なし
パスワード
   こんにちは。かみちゃん　です。

>※csvファイルは，1行で構成されている（内容も同じ順）
>※最終的には，全csvを1シートにしたい

Dir関数で特定のフォルダのすべてのCSVファイルを取得する。
Openステートメントで、テキストモードで開く
1行だけ読み込む
セルに書き込む

このような手順になるかと思います。
これらは、次のようにすればできると思います。
ひとつひとつのコードは、ヘルプ等でまずは調べるようにしてください。

Option Explicit
Sub Macro1()
　Dim MyPath As String
　Dim MyName As String
　Dim OpenFileName As String
　Dim n As Long
　Dim buf As Variant
　Dim tmp As String
　Dim RowNo As Long

　MyPath = ThisWorkbook.Path ' CSVのフォルダ名の指定
　MyName = Dir(MyPath & "\*.csv") 'CSVファイルすべて
　RowNo = 1
　Do While MyName <> ""　　' ループを開始します。
　　'元のCSVファイル名のフルパス
　　OpenFileName = MyPath & "\" & MyName
　　
　　'変更したファイルをテキストモードで開く
　　n = FreeFile
　　Open OpenFileName For Input As #n
　　'最初の1行を読み込む
　　Line Input #n, tmp
　　Close #n
　　'カンマごとに区切る
　　buf = Split(tmp, ",")
　　'Ax:Dx（xは行番号）セルに書き込む
　　Range("A" & RowNo & ":D" & RowNo) = buf
　　'行番号をカウントアップ
　　RowNo = RowNo + 1
　　'次のファイルを探す
　　MyName = Dir
　Loop
　MsgBox "終了"
End Sub
【25956】Re:複数csvファイルの読込み
お礼  ひろし  - 05/6/20(月) 0:40 -
引用なし
パスワード
   素晴らしいです！！

動きました．
（最初は，csvファイルの作り方が拙くて，ちゃんと認識されません
　でしたが．．．）

DIRなんて関数が．．．（知ってても，こんな使い方思いつきませんが）

有難うございました．
  新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム  
9708 / 13657 ﾂﾘｰ ←次へ　｜　前へ→
ページ：  ┃  記事番号：
2610219
(SS)C-BOARD v3.8 is Free