| |
▼やっぱり猫が好き さん：
かなり丸投げな感じの投稿ですが・・
興味が湧いたので作ってみました。
サムネイル表示したいということだと思いますが、
提示したコードで？？なら専用のデジカメソフトでも買ったほうが良いと思います。
JPGファイルは同じフォルダ内(サブフォルダなし）にあり
コードのあるxlsファイルが同一フォルダにある。
UserForm1にListBox1,CommandButton１を作成。
位置とサイズは、_Initializeの
Pic_Size,Ran をウマいこと調整してみてください。
'UserForm1モジュール
Option Explicit
Private myPath As String
Private Pic_Size As Single
Private Ran As Range
Private Sub UserForm_Initialize()
Dim myFile As String
Dim Dir_Type As String
Pic_Size = 0.23 '画像の大きさを指定
myPath = ThisWorkbook.Path & "\" '画像ファイルのあるPath & "\"を指定
Dir_Type = "*.JPG"
With ActiveSheet
Set Ran = .Range("A5,E5,A15,E15,A25,E25") '貼り付ける場所を指定
End With
myFile = Dir(myPath & Dir_Type)
Do Until myFile = ""
ListBox1.AddItem myFile
myFile = Dir()
Loop
ListBox1.MultiSelect = fmMultiSelectMulti
End Sub
Private Sub CommandButton1_Click()
Dim i As Integer
Dim j As Integer
j = 1
For i = 0 To ListBox1.ListCount - 1
If ListBox1.Selected(i) = True Then
If j > Ran.Areas.Count Then
MsgBox "選択枚数が" & Ran.Areas.Count & "を越えています"
Exit Sub
End If
Ran.Areas(j).Activate
With ActiveSheet.Pictures.Insert(myPath & ListBox1.List(i))
.ShapeRange.ScaleWidth Pic_Size, msoFalse, msoScaleFromTopLeft
.ShapeRange.ScaleHeight Pic_Size, msoFalse, msoScaleFromTopLeft
End With
j = j + 1
End If
Next i
End Sub
|
|
![[未読]](./data/excel/image/read_icon.gif){kind=icon}
