Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちら をご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。

  新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム  
6470 / 13644 ﾂﾘｰ ←次へ　｜　前へ→
▼ 【44953】数字が変化したとき背景色が自動的に変わるようにしたい。 shellken 06/12/7(木) 20:48 質問[未読]
【44954】Re:数字が変化したとき背景色が自動的に変... maverick 06/12/7(木) 21:15 回答[未読]
【44975】Re:数字が変化したとき背景色が自動的に変... shellken 06/12/8(金) 16:16 質問[未読]
【44978】Re:数字が変化したとき背景色が自動的に変... maverick 06/12/8(金) 17:19 回答[未読]
【44984】Re:数字が変化したとき背景色が自動的に変... shellken 06/12/8(金) 20:27 質問[未読]
【44991】Re:数字が変化したとき背景色が自動的に変... maverick 06/12/8(金) 22:23 回答[未読]
【44999】Re:数字が変化したとき背景色が自動的に変... shellken 06/12/9(土) 14:25 質問[未読]
【45013】Re:数字が変化したとき背景色が自動的に変... maverick 06/12/9(土) 23:59 回答[未読]
【45042】Re:数字が変化したとき背景色が自動的に変... shellken 06/12/10(日) 22:03 質問[未読]
【45055】Re:数字が変化したとき背景色が自動的に変... maverick 06/12/11(月) 12:58 回答[未読]
【45045】Re:数字が変化したとき背景色が自動的に変... shellken 06/12/10(日) 23:40 質問[未読]
【45056】Re:数字が変化したとき背景色が自動的に変... maverick 06/12/11(月) 13:07 発言[未読]
【45064】Re:数字が変化したとき背景色が自動的に変... shellken 06/12/11(月) 17:14 お礼[未読]
【44983】Re:数字が変化したとき背景色が自動的に変... shun 06/12/8(金) 19:58 回答[未読]
【44985】Re:数字が変化したとき背景色が自動的に変... shellken 06/12/8(金) 20:41 質問[未読]
【44986】Re:数字が変化したとき背景色が自動的に変... shun 06/12/8(金) 21:29 回答[未読]
【44993】Re:数字が変化したとき背景色が自動的に変... shellken 06/12/8(金) 23:09 質問[未読]
【45030】Re:数字が変化したとき背景色が自動的に変... Toshiyo 06/12/10(日) 16:32 質問[未読]
【45040】Re:数字が変化したとき背景色が自動的に変... shellken 06/12/10(日) 20:16 回答[未読]
【45041】Re:数字が変化したとき背景色が自動的に変... ToShiYo 06/12/10(日) 21:19 質問[未読]
【45044】Re:数字が変化したとき背景色が自動的に変... shellken 06/12/10(日) 23:32 回答[未読]
【45046】Re:数字が変化したとき背景色が自動的に変... ponpon 06/12/11(月) 0:21 発言[未読]
【45048】Re:数字が変化したとき背景色が自動的に変... ToShiYo 06/12/11(月) 7:50 お礼[未読]
【45063】Re:数字が変化したとき背景色が自動的に変... shellken 06/12/11(月) 16:44 質問[未読]
【45069】Re:数字が変化したとき背景色が自動的に変... ponpon 06/12/11(月) 23:30 発言[未読]
【44953】数字が変化したとき背景色が自動的に変わ...
質問  shellken  - 06/12/7(木) 20:48 -
引用なし
パスワード
   Excelのsheet1のあるセルにあらかじめ数字があるとします。
たとえばA1のセルに100と書いてあるとします。
それ以外の場所にもいろいろな数字が書いてあります。

あるプログラム（株価を知らせてくれるプログラムなのですが）がExcelを認識し、たとえばA1の内容をを100から自動的に200に書き換えます。
その仕組みは、A1などのセルにはそのプログラムで認識できる、決められた関数が書いてあって、インターネットを通じて、Excelに送信してくれるため数字が変わる様になっています。
関数といっても簡単で、たとえば「=銘柄名.現在値」をA1のセルに書いておけば「=銘柄名.現在値」が変わったときにその銘柄の現在値をExcelに送ってくれるので数字が変わります。

このときに数字が大きくなったらそのセルの背景色を赤、小さくなったら背景色を緑に自動的な変えたいと思うのですが、マクロをどのように組んだらよいでしょうか？
ちなみに数字が変わるときは入力しているわけではないので、フォーカスはそのセルに移りません。（というかセルの枠が太くならないので移っていないと思います。）

VBAのsheet1というモジュールをダブルクリックしたら、
Private sub Worksheet Change (ByVal Target As Range)
というイベントがあったので、この中になにかコードを書けばうまくいきそうだと思っているのですが。
【44954】Re:数字が変化したとき背景色が自動的に...
回答  maverick  - 06/12/7(木) 21:15 -
引用なし
パスワード
   シートモジュール
Public vl As Long

Private Sub Worksheet_Calculate()
　　With Range("A1")
　　　　If .Value > vl Then
　　　　　　.Interior.ColorIndex = 3
　　　　ElseIf .Value < vl Then
　　　　　　.Interior.ColorIndex = 4
　　　　End If
　　vl = .Value
　　End With
End Sub
【44975】Re:数字が変化したとき背景色が自動的に...
質問  shellken  - 06/12/8(金) 16:16 -
引用なし
パスワード
   ありがとうございました。
このコードで確かにA1の数字が変わったときに思った通りにできました。
しかしシート上のセルのいろんなところたとえばA行すべてが変化しうる場合（たとえばA1からA300まで）はどうしたらいいのでしょう？
【44978】Re:数字が変化したとき背景色が自動的に...
回答  maverick  - 06/12/8(金) 17:19 -
引用なし
パスワード
   応用してください、配列を使えば出来ます。
ただし、処理時間 ＞ 次の更新までの時間　になるようだと
固まるかもしれません。

Private vl(1 To 300) As Long

Private Sub Worksheet_Calculate()
　　Dim i As Long
　　For i = 1 To 300
　　　　With Cells(i, 1)
　　　　　　If .Value > vl(i) Then
　　　　　　　　.Interior.ColorIndex = 3
　　　　　　ElseIf .Value < vl(i) Then
　　　　　　　　.Interior.ColorIndex = 4
　　　　　　End If
　　　　vl(i) = .Value
　　　　End With
　　Next i
End Sub

※B列、C列となる場合は２次元配列にすればよいでしょう
【44983】Re:数字が変化したとき背景色が自動的に...
回答  shun  - 06/12/8(金) 19:58 -
引用なし
パスワード
   ▼shellken さん：
>Excelのsheet1のあるセルにあらかじめ数字があるとします。
>このときに数字が大きくなったらそのセルの背景色を赤、小さくなったら背景色を緑に自動的な変えたいと思うのですが、マクロをどのように組んだらよいでしょうか？

VBA質問箱は、おひさしぶりです。
横レスですが、この質問内容だとVBAを使わなくても
メニューの「書式」→「条件付書式」で出来ると思いますが・・・
ただし、設定できる条件は3つまでです。
【44984】Re:数字が変化したとき背景色が自動的に...
質問  shellken  - 06/12/8(金) 20:27 -
引用なし
パスワード
   ありがとうございます。
うまくいきました。


しかし疑問が一つ残りました
自分でPrivate vl(1 To 300) As Longと
定義したvl(i)が元のセル(i, 1)の書き換えられる前の値、
Cells(i, 1).Value が書き換えられた後の値と見ていいんでしょうか？
そうするとvl(i)は、自分で定義したものなのに、元のセル(i, 1)に入っていた値になるのはどういう仕組みがあるのかわかりません。

それともvlというのが元々のセルに入っていたものという約束でもあるのでしょうか？
何も定義がないとしたら、うまく認識されることが不思議です。
Cells(i, 1).Valueがセル(i, 1)にある値というのはプロパティと思えば理解できます。
【44985】Re:数字が変化したとき背景色が自動的に...
質問  shellken  - 06/12/8(金) 20:41 -
引用なし
パスワード
   条件付き書式の設定ダイアログボックスの右上の欄にどのように入れたらいいのかよくわかりませんでした。
つまり条件1のところで
「セルの値が」→「次の値より大きい」→「ここになんと入れるか？」
わかりません。
セルをいくつか選択してenterキーを押すと記号が挿入されますが、その後、OKボタンを押したときにエラーメッセージが出て、うまく書式設定できませんでした。
【44986】Re:数字が変化したとき背景色が自動的に...
回答  shun  - 06/12/8(金) 21:29 -
引用なし
パスワード
   ▼shellken さん：
>条件付き書式の設定ダイアログボックスの右上の欄にどのように入れたらいいのかよくわかりませんでした。
>つまり条件1のところで
>「セルの値が」→「次の値より大きい」→「ここになんと入れるか？」
>わかりません。
>セルをいくつか選択してenterキーを押すと記号が挿入されますが、その後、OKボタンを押したときにエラーメッセージが出て、うまく書式設定できませんでした。

1.まず背景色を設定するセル範囲を選択します。
2.メニューの「書式」→「条件付書式」
3.「条件1」で「セルの値が」→「次の値以上」→「赤色にする数値の下限値を入力」
4.書式ボタンをクリック→「パターン」タブでカラーパネルの赤色をクリック→「追加」ボタンをクリック
5.「条件2」で「セルの値が」→「次の値より小さい」→「緑色にする数値の上限値を入力」
6.書式ボタンをクリック→「パターン」タブでカラーパネルの緑色をクリック→「OK」ボタンをクリック

と、こんな具合です。
【44991】Re:数字が変化したとき背景色が自動的に...
回答  maverick  - 06/12/8(金) 22:23 -
引用なし
パスワード
   >しかし疑問が一つ残りました
>自分でPrivate vl(1 To 300) As Longと
>定義したvl(i)が元のセル(i, 1)の書き換えられる前の値、
>Cells(i, 1).Value が書き換えられた後の値と見ていいんでしょうか？
そうです
>そうするとvl(i)は、自分で定義したものなのに、元のセル(i, 1)に入っていた値になるのはどういう仕組みがあるのかわかりません。
>
↓これです
>　　　　vl(i) = .Value
※vl(i)の初期値は1から300まで全て0です


↓で test() を実行して確認してみて下さい

'標準モジュール
Sub test()
　　For i = 1 To 5
　　　　Range("A1").Value = 2 ^ i
　　Next i
End Sub

'シートモジュール
Private vl As Long

Private Sub Worksheet_Change(ByVal Target As Range)
　　If Target.Address = "$A$1" Then
　　　　MsgBox "A1セルの現在の値： " & Range("A1").Value & _
　　　　　　　　vbCrLf & "A1セルの変更前の値：" & vl
　　　　vl = Range("A1").Value
　　End If
End Sub
【44993】Re:数字が変化したとき背景色が自動的に...
質問  shellken  - 06/12/8(金) 23:09 -
引用なし
パスワード
   今回の場合最初に何らかの数字が入っていてその数字が変化したとき、
「大きくなったとき、背景を赤にする」、
「小さくなったとき、背景を緑にする」
ということなので、「数値の下限上限」は関係しません。
ということはこのやり方ではできないのではないでしょうか？
【44999】Re:数字が変化したとき背景色が自動的に...
質問  shellken  - 06/12/9(土) 14:25 -
引用なし
パスワード
   非常時よくわかりました。
そしてうまくいきました。
うまくいったら少し物足りなくなりました。
それは、数字が変化するとき、背景が３回ぐらい点滅して赤く変わるようにできないかと思いました。
実現できるのでしょうか？
VB.NETと違い、タイマーコントロールがないので、できないような気がしますが。
【45013】Re:数字が変化したとき背景色が自動的に...
回答  maverick  - 06/12/9(土) 23:59 -
引用なし
パスワード
   こんな感じですか？

'標準モジュール
Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Function test(cnt As Variant, col As Long)
　　For j = LBound(cnt) To UBound(cnt)
　　　　Cells(cnt(j), 1).Interior.ColorIndex = col
　　Next j
　　Sleep 100
End Function


'シートモジュール
Private vl(1 To 300) As Long

Private Sub Worksheet_Calculate()
　　Dim i As Long, rng As String, cnt As Variant
　　For i = 1 To 300
　　　　With Cells(i, 1)
　　　　　　If .Value > vl(i) Then
　　　　　　　　rng = rng & i & ","
　　　　　　　　.Interior.ColorIndex = 3
　　　　　　ElseIf .Value < vl(i) Then
　　　　　　　　.Interior.ColorIndex = 4
　　　　　　Else
　　　　　　　　.Interior.ColorIndex = 0
　　　　　　End If
　　　　vl(i) = .Value
　　　　End With
　　Next i
　　If rng <> "" Then
　　　　cnt = Split(Left(rng, Len(rng) - 1), ",")
　　　　For i = 1 To 4
　　　　　　Call test(cnt, 0)
　　　　　　Call test(cnt, 3)
　　　　Next i
　　End If
End Sub
【45030】Re:数字が変化したとき背景色が自動的に...
質問  Toshiyo  - 06/12/10(日) 16:32 -
引用なし
パスワード
   ▼shellken さん：
横からすみません、一件質問させていただきます。

Private Sub Worksheet_Calculate()
で始まる、このコードは実際どのように
操作させるのでしょうか。
ボタンとリンクさせることも出来ませんし、
イベントマクロ（WorkSheet_Changeのような）として
動くわけでもないですし・・・

ステップインでは動作が良く分かるのですが･･･
【45040】Re:数字が変化したとき背景色が自動的に...
回答  shellken  - 06/12/10(日) 20:16 -
引用なし
パスワード
   Private Sub Worksheet_Calculate()
で始まる、このコードは
VBAの編集画面左上の
VBAProject-Sheet1(Seet1)をダブルクリックすると出てくるところにそのまま貼り付けています。
そうしておくだけで、ボタンなどがなくてもシート上の数字が変わったというイベントが発生したことをVBAが認識し、うまく動いてくれます。
【45041】Re:数字が変化したとき背景色が自動的に...
質問  ToShiYo  - 06/12/10(日) 21:19 -
引用なし
パスワード
   ▼shellken さん：
今晩は。ありがとうございます。
ご指摘の通りしておりますが
つまり
Private Sub Worksheet_Change(ByVal Target As Range)
等と同じVBAProject-Sheet1(Seet1)のダブルクリックで出る
ところですね。
そのようにしているのですが、数字の変化に追随してイベントが
発生しないのですが・・・
モジュールレベルの変数とプロシジャーレベルの変数をshellkenさんが
書かれていたのを興味深く見させていただいていたのですが・・・
下のコードですが、A7に例えば100を入れ、その後80を入れると
A7のセルが緑になり、その後更に81を入れるとセルの色が赤になる
ということですね。
その動きが見られないのです。ステップインでは正しく動くのですが･･･
何か問題があるのでしょうか？

Public vl As Long

Private Sub Worksheet_Calculate()
　　With Range("A7")
　　　　If .Value > vl Then
　　　　　　.Interior.ColorIndex = 3
　　　　ElseIf .Value < vl Then
　　　　　　.Interior.ColorIndex = 4
　　　　End If
　　vl = .Value
　　End With
End Sub
【45042】Re:数字が変化したとき背景色が自動的に...
質問  shellken  - 06/12/10(日) 22:03 -
引用なし
パスワード
   急に難しくなりました。
私の環境下では、サンプルとは少し違い
、今以下のコードを使って、AI列の数字が変わったときAH列の数字より大きいとき、
AI列の数字の背景が赤、小さいとき緑に変わるようにしました。

===============================================================
Private Sub Worksheet_Calculate()
　　On Error Resume Next
　　Dim i As Long
　　For i = 2 To 301
　　　 With Cells(i, 35)
　　　　　 If Cells(i, 34).Value <> 0 Then
　　　　　　　 If .Value > Cells(i, 34).Value Then
　　　　　　　　　 .Interior.ColorIndex = 3
　　　　　　　　　 .Font.ColorIndex = 2
　　　　　　　　ElseIf .Value < Cells(i, 34).Value Then
　　　　　　　　　　.Interior.ColorIndex = 10
　　　　　　　　　　.Font.ColorIndex = 2
　　　　　　　 End If
　　　　　　End If
　　　 End With
　　Next i
End sub
============================================================
AH列の数字はAI列の数字の変化前の数字が来るようにしてありますのでやりたいことは実現しているわけです。
しかし今回の新しく示してもらったコードを適用しようとすると、変化した数字のところではなくその他いくつかの部分が赤く点滅します。
（i,1）の部分を（i,35）に変えてみるとA列ではなく、AI列が点滅するようになりましたが、数字が変化したところの上下いくつか離れた場所が点滅します。
しかも赤色のみの点滅です。
ちょっと今回の例題のコードを解読したいのでいくつか質問します。

1.rng = rng & i & ","
のrng というのはどこで定義しているのでしょうか？
またrng & i & ","の意味は？

2.For j = LBound(cnt) To UBound(cnt)
のLBound、UBoundの使い方にとまどっています。
（定義は調べたが、その意味がいまいちよくわからない）

3.cnt = Split(Left(rng, Len(rng) - 1), ",")
の意味の解読が難しいです。
【45044】Re:数字が変化したとき背景色が自動的に...
回答  shellken  - 06/12/10(日) 23:32 -
引用なし
パスワード
   すみません。
私の環境でも同様の現象が発生していて、このコードを別のシートのところに貼る、または新規BOOKを作って同じことをしようとするとイベントが発生しません。
今原因を調査中です。
私が実際に使っているシート上ではうまくいきます。

私の質問に答えてくれているmaverickさんは非常にVBAの知識が深いようですのでそちらに聞いてみてもいいと思います。
【45045】Re:数字が変化したとき背景色が自動的に...
質問  shellken  - 06/12/10(日) 23:40 -
引用なし
パスワード
   maverick さん：
このコードを新規BOOKから、もう一度microsoft Excel Object のsheet1(sheet1)をダブルクリックしたところに貼り付けましたがイベントが発生しません。
何か他にすることがあったでしょうか？
以前貼り付けたBOOKではうまくいきます。
【45046】Re:数字が変化したとき背景色が自動的に...
発言  ponpon  - 06/12/11(月) 0:21 -
引用なし
パスワード
   >Private Sub Worksheet_Calculate()
シートが再計算されたときに発生するイベント
セルに関数や数式などが入れられていて、再計算されるときに発生します。

>Private Sub Worksheet_Change(ByVal Target As Range)
シートのTargetの値が発生したときに発生します。
Targetを指定しないと、シート上の値が変化したときに発生します。

ただ単にA7の値（数字）が変化したときなら
こんな感じかな？

Private Sub Worksheet_Change(ByVal Target As Range)
　　With Target
　　　　If Not .Address(0, 0) = "A7" Then Exit Sub
　　　　If .Value > vl Then
　　　　　　.Interior.ColorIndex = 3
　　　　ElseIf .Value < vl Then
　　　　　　.Interior.ColorIndex = 4
　　　　End If
　　　　vl = .Value
　　End With

End Sub
【45048】Re:数字が変化したとき背景色が自動的に...
お礼  ToShiYo  - 06/12/11(月) 7:50 -
引用なし
パスワード
   ▼ponpon さん：

ありがとうございました。理解できました。

>>Private Sub Worksheet_Calculate()
>シートが再計算されたときに発生するイベント
>セルに関数や数式などが入れられていて、再計算されるときに発生します。

→44991がそれに相当するのですね。
【45055】Re:数字が変化したとき背景色が自動的に...
回答  maverick  - 06/12/11(月) 12:58 -
引用なし
パスワード
   >急に難しくなりました。
>私の環境下では、サンプルとは少し違い
>、今以下のコードを使って、AI列の数字が変わったときAH列の数字より大きいとき、
>AI列の数字の背景が赤、小さいとき緑に変わるようにしました。
>
>===============================================================
>Private Sub Worksheet_Calculate()
>　　On Error Resume Next
>　　Dim i As Long
>　　For i = 2 To 301
>　　　 With Cells(i, 35)
>　　　　　 If Cells(i, 34).Value <> 0 Then
>　　　　　　　 If .Value > Cells(i, 34).Value Then
>　　　　　　　　　 .Interior.ColorIndex = 3
>　　　　　　　　　 .Font.ColorIndex = 2
>　　　　　　　　ElseIf .Value < Cells(i, 34).Value Then
>　　　　　　　　　　.Interior.ColorIndex = 10
>　　　　　　　　　　.Font.ColorIndex = 2
>　　　　　　　 End If
>　　　　　　End If
>　　　 End With
>　　Next i
>End sub
>============================================================
>AH列の数字はAI列の数字の変化前の数字が来るようにしてありますのでやりたいことは実現しているわけです。
>しかし今回の新しく示してもらったコードを適用しようとすると、変化した数字のところではなくその他いくつかの部分が赤く点滅します。
>（i,1）の部分を（i,35）に変えてみるとA列ではなく、AI列が点滅するようになりましたが、数字が変化したところの上下いくつか離れた場所が点滅します。
私のコードをそのまま使用したときはどうでしたか？
私のところでは問題なく動いています。

>しかも赤色のみの点滅です。
そのようにしましたが？
>>それは、数字が変化するとき、背景が３回ぐらい点滅して赤く変わるようにできないかと思いました。
と質問されているので。


>ちょっと今回の例題のコードを解読したいのでいくつか質問します。
>
>1.rng = rng & i & ","
>のrng というのはどこで定義しているのでしょうか？
↓ここです
>　　Dim i As Long, rng As String, cnt As Variant

>またrng & i & ","の意味は？
 i を","区切りの文字列にしています。
区切り文字は","でなくても構いません( @ や / などでもＯＫ)
>　　　　End With
>　　Next i
の後に
　　Debug.Print rng
と入れて確認してみてください

>
>2.For j = LBound(cnt) To UBound(cnt)
>のLBound、UBoundの使い方にとまどっています。
>（定義は調べたが、その意味がいまいちよくわからない）
配列のインデックス番号の下限（LBound）、上限（UBound）を調べられます。
試してみてください。
Sub test()
　　Dim test1(0 To 5) As Integer
　　Dim test2(2 To 8) As Integer
　　Debug.Print LBound(test1), UBound(test1), LBound(test2), UBound(test2)
End Sub
※私は、LowerBound、UpperBound として覚えています。

>3.cnt = Split(Left(rng, Len(rng) - 1), ",")
>の意味の解読が難しいです。
区切り文字を元に文字列を分割しています。
Left(rng, Len(rng) - 1) は右端の余分な区切り文字を取り除いてます。
【45056】Re:数字が変化したとき背景色が自動的に...
発言  maverick  - 06/12/11(月) 13:07 -
引用なし
パスワード
   ▼shellken さん：
>maverick さん：
>このコードを新規BOOKから、もう一度microsoft Excel Object のsheet1(sheet1)をダブルクリックしたところに貼り付けましたがイベントが発生しません。
>何か他にすることがあったでしょうか？
>以前貼り付けたBOOKではうまくいきます。
 ponpon さんが回答されている通りですね。
Calculate(計算する)時に発生するイベントです。
【45063】Re:数字が変化したとき背景色が自動的に...
質問  shellken  - 06/12/11(月) 16:44 -
引用なし
パスワード
   いろいろなやり方があって、おもしろーいです。
正確には
Public vl As Long
を最初につける必要がありました。

ところで、A7だけでなくA列全体をそうしたいときとかA1からA3の間だけそうしたいときはどうすればよいのですか。

また、変化するときに大きくなるときは赤、小さくなるときは緑で３回くらい点滅させることできますか。（できるだけ簡単な方法がいいです。）
【45064】Re:数字が変化したとき背景色が自動的に...
お礼  shellken  - 06/12/11(月) 17:14 -
引用なし
パスワード
   maverick さん、ありがとうございました。

あの難しい点滅するコードに関してはいま分析中です。
もうしばらくお待ちください。
【45069】Re:数字が変化したとき背景色が自動的に...
発言  ponpon  - 06/12/11(月) 23:30 -
引用なし
パスワード
   ▼shellken さん：
>ところで、A7だけでなくA列全体をそうしたいときとかA1からA3の間だけそうしたいときはどうすればよいのですか。

コードの意味を理解して応用するようにいましょう。

>また、変化するときに大きくなるときは赤、小さくなるときは緑で３回くらい点滅させることできますか。（できるだけ簡単な方法がいいです。）

maverickさんが詳しく回答しているのを応用しましょう。

'標準モジュールに
'maverickさんのを利用して

Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Function test(rng As Range, col As Long)
　　　　Cells(rng.Row, rng.Column).Interior.ColorIndex = col
　　Sleep 100
End Function

'====================================================
'シートモジュールに
'私のとmaverickさんのを合体させて、一度に複数セルの変化(コピペなど）には
'対応していません。
'私の力量では、こんな不細工なコードになります。

Private Sub Worksheet_Change(ByVal Target As Range)
　　Dim i As Long, j As Long
　　Dim myVal As Long, vl As Long
　　With Target
　　　　If .Count > 1 Then Exit Sub
　　　　If IsEmpty(.Value) Then Exit Sub
　　　　If Application.Intersect(Target, Range("A:A")) Is Nothing Then _
　　　　　 Exit Sub　　　　　　　　　　　　　'↑A列全体
　　　　Application.EnableEvents = False
　　　　myVal = .Value
　　　　Application.Undo
　　　　vl = .Value
　　　　.Value = myVal
　　　　If .Value > vl Then
　　　　　　i = 3
　　　　　　.Interior.ColorIndex = i
　　　　ElseIf .Value < vl Then
　　　　　　i = 4
　　　　　　.Interior.ColorIndex = i
　　　　Else
　　　　　　i = 0
　　　　　　.Interior.ColorIndex = i
　　　　End If
　　　　
　　　　Application.EnableEvents = True
　　End With
　　 For j = 1 To 4
　　　　Call test(Target, 0)
　　　　Call test(Target, i)
　　 Next
End Sub
  新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム  
6470 / 13644 ﾂﾘｰ ←次へ　｜　前へ→
ページ：  ┃  記事番号：
2610219
(SS)C-BOARD v3.8 is Free