Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

1454 / 13644 ﾂﾘｰ

←次へ　｜　前へ→

▼

【74321】文字の比較 愛子 13/5/22(水) 17:13

【74328】Re:文字の比較 UO3 13/5/23(木) 11:13

【74330】Re:文字の比較 愛子 13/5/23(木) 12:34

【74331】Re:文字の比較 愛子 13/5/23(木) 12:43

【74332】Re:文字の比較 UO3 13/5/23(木) 14:22

【74333】Re:文字の比較 愛子 13/5/23(木) 17:09

【74334】Re:文字の比較 愛子 13/5/23(木) 18:21

【74335】Re:文字の比較 UO3 13/5/23(木) 19:58

【74337】Re:文字の比較 愛子 13/5/23(木) 21:21

【74340】Re:文字の比較 UO3 13/5/24(金) 10:17

【74344】Re:文字の比較 愛子 13/5/24(金) 12:55

【74347】Re:文字の比較 UO3 13/5/24(金) 13:16

【74350】Re:文字の比較 愛子 13/5/24(金) 15:20

【74352】Re:文字の比較 愛子 13/5/24(金) 18:24

【74353】Re:文字の比較 UO3 13/5/24(金) 19:37

【74354】Re:文字の比較 愛子 13/5/24(金) 20:27

【74341】Re:文字の比較 UO3 13/5/24(金) 10:42

【74346】Re:文字の比較 愛子 13/5/24(金) 13:14

【74342】Re:文字の比較 UO3 13/5/24(金) 11:15

【74345】Re:文字の比較 愛子 13/5/24(金) 12:57

【74343】Re:文字の比較 UO3 13/5/24(金) 11:20

【74329】Re:文字の比較 UO3 13/5/23(木) 11:34


	【74321】文字の比較

愛子 - 13/5/22(水) 17:13 -


	引用なし

	パスワード

ａシートからｂシートにデータを転記します。
ｂシートはＡ列からＬ列まであります。
内、Ｅ列の項目は、名前　　Ｌ列の項目は、金額です。
Ｅ列の名前はａシートで任意に入力された名前です。
Ｎ列は全員の名前です。
質問：Ｎ列の名前とＥ列の名前が一致すればＮ列の右セル（Ｏ列）に
Ｎ列の名前の金額（Ｌ列）を貼り付ける方法を教えて下さい。

　例：Ｅ列３行目の名前　大木、　Ｌ列３行目の金額　50,000
　　　Ｎ列８行目の名前　大木　　Ｏ列８行目　に50,000と貼り付ける方法です。

宜しくお願いします。
　　　


	【74328】Re:文字の比較

UO3 - 13/5/23(木) 11:13 -


	引用なし

	パスワード

▼愛子さん：

こんにちは

シートの関係を確認させてください

・まず、aシートの情報を、bシートで名前がマッチしたところに貼り付けるんですね？
・で、Ｅ，Ｌ列の説明がありますが、これは a シートですね？
・その　a シートで入力した名前が b　シートのＮ列にあれば、その行のＯ列に金額転記ですね？

こんな理解でいいですか？


	【74329】Re:文字の比較

UO3 - 13/5/23(木) 11:34 -


	引用なし

	パスワード

▼愛子さん：

とりあえず↑の理解でコード案を２つほど。
なお、aシートもbシートも１行目がタイトル行、データは２行目からという想定です。

Sub Sample1()
'ループでシート関数MATCHを使う基本形。処理効率は若干落ちる。
　　Dim nameV As Variant
　　Dim amtV As Variant
　　Dim newV As Variant
　　Dim i As Long
　　Dim z As Variant
　　
　　With Sheets("a")
　　　　'aシートの名前列と金額列を配列に格納（２行目以降）
　　　　With .Range("E2", .Range("E" & .Rows.Count).End(xlUp))
　　　　　　nameV = .Cells.Value
　　　　　　amtV = .Offset(, 7).Value
　　　　End With
　　End With
　　
　　With Sheets("b")
　　　　'bシートの N列、O列の内容（２行目以降）を配列に格納
　　　　newV = .Range("N2", .Range("N" & .Rows.Count).End(xlUp)).Resize(, 2).Value
　　　　For i = 1 To UBound(newV, 1)
　　　　　　z = Application.Match(newV(i, 1), nameV, 0)
　　　　　　If IsNumeric(z) Then newV(i, 2) = amtV(z, 1)
　　　　Next
　　　　.Range("N2").Resize(UBound(newV, 1), UBound(newV, 2)).Value = newV
　　　　.Select
　　End With
　　
End Sub

Sub Sample2()
'Dictionary処理案。
　　Dim c As Range
　　Dim newV As Variant
　　Dim i As Long
　　Dim dic As Object
　　
　　Set dic = CreateObject("Scripting.Dictionary")
　　
　　With Sheets("a")
　　　　'aシートの名前と金額をDictionaryに格納（２行目以降）
　　　　For Each c In .Range("E2", .Range("E" & .Rows.Count).End(xlUp))
　　　　　　dic(c.Value) = c.EntireRow.Range("L1").Value
　　　　Next
　　End With
　　
　　With Sheets("b")
　　　　'bシートの N列、O列の内容（２行目以降）を配列に格納
　　　　newV = .Range("N2", .Range("N" & .Rows.Count).End(xlUp)).Resize(, 2).Value
　　　　For i = 1 To UBound(newV, 1)
　　　　　　If dic.exists(newV(i, 1)) Then newV(i, 2) = dic(newV(i, 1))
　　　　Next
　　　　.Range("N2").Resize(UBound(newV, 1), UBound(newV, 2)).Value = newV
　　　　.Select
　　End With
　　
End Sub


	【74330】Re:文字の比較

愛子

- 13/5/23(木) 12:34 -


	引用なし

	パスワード

▼UO3 さん：
こんにちは、
今回もお世話になります。

UO3様>シートの関係を確認させてください
>
>・まず、aシートの情報を、bシートで名前がマッチしたところに貼り付けるんですね？
--愛子；説明不足ですみません。一旦ａシート（ａからｌ迄のデータ）の
情報をｂシートにデータ管理として全て貼り付けます。

>・で、Ｅ，Ｌ列の説明がありますが、これは a シートですね？--愛子；これは、ｂシートです。

>愛子；UO3様の言葉を少し替えさせて頂きました。---・その　ｂシートに転記
された内、名前（Ｅ列）が b　シートのＮ列にあれば、その行のＯ列に金額転記をします。
>


	【74331】Re:文字の比較

愛子

- 13/5/23(木) 12:43 -


	引用なし

	パスワード

ＵＯ３様
ａシートからｂシートへ転記という事を書かなければよかったです。
一致するデータはｂシート上で比較しますので、
折角コードを書いて頂き申し訳ありませんが、ａシートは忘れて頂きｂシート
上での比較だけでお願いします。


	【74332】Re:文字の比較

UO3 - 13/5/23(木) 14:22 -


	引用なし

	パスワード

▼愛子さん：

それではシート b だけを相手にして。
アップ済みの Sample1 にあたるのが Sample11、Sample2　にあたるものが Sample22です。

Sub Sample11()
'ループでシート関数MATCHを使う基本形。処理効率は若干落ちる。
　　Dim nameV As Variant
　　Dim amtV As Variant
　　Dim newV As Variant
　　Dim i As Long
　　Dim z As Variant
　
　　With Sheets("b")
　　　　'bシートの名前列と金額列を配列に格納（２行目以降）
　　　　With .Range("E2", .Range("E" & .Rows.Count).End(xlUp))
　　　　　　nameV = .Cells.Value
　　　　　　amtV = .Offset(, 7).Value
　　　　End With
　　　　'bシートの N列、O列の内容（２行目以降）を配列に格納
　　　　newV = .Range("N2", .Range("N" & .Rows.Count).End(xlUp)).Resize(, 2).Value
　　　　For i = 1 To UBound(newV, 1)
　　　　　　z = Application.Match(newV(i, 1), nameV, 0)
　　　　　　If IsNumeric(z) Then newV(i, 2) = amtV(z, 1)
　　　　Next
　　　　.Range("N2").Resize(UBound(newV, 1), UBound(newV, 2)).Value = newV
　　　　.Select
　　End With
　
End Sub

Sub Sample22()
'Dictionary処理案。
　　Dim c As Range
　　Dim newV As Variant
　　Dim i As Long
　　Dim dic As Object
　
　　Set dic = CreateObject("Scripting.Dictionary")
　
　　With Sheets("b")
　　　　'bシートの名前と金額をDictionaryに格納（２行目以降）
　　　　For Each c In .Range("E2", .Range("E" & .Rows.Count).End(xlUp))
　　　　　　dic(c.Value) = c.EntireRow.Range("L1").Value
　　　　Next
　　　　'bシートの N列、O列の内容（２行目以降）を配列に格納
　　　　newV = .Range("N2", .Range("N" & .Rows.Count).End(xlUp)).Resize(, 2).Value
　　　　For i = 1 To UBound(newV, 1)
　　　　　　If dic.exists(newV(i, 1)) Then newV(i, 2) = dic(newV(i, 1))
　　　　Next
　　　　.Range("N2").Resize(UBound(newV, 1), UBound(newV, 2)).Value = newV
　　　　.Select
　　End With
　
End Sub


	【74333】Re:文字の比較

愛子

- 13/5/23(木) 17:09 -


	引用なし

	パスワード

▼UO3 さん：
ご面倒かけてすみませんでした。
２種類のコードをラーンしましたが、一致したデータの金額はうまく拾ってくる
のですが、一致した金額を合計するとそれぞれ違うのです。

私は、丸投げしてはいけないと思い、同じデータを集計た後で、可視セル状態にしてからコピー、貼り付けをし
そこで教えて頂いた一致するＶＢＡを走らせるつもりでした。

可視セルで張り付けたデータで一致した金額をチェックすると、これまた２種類のコードでラーンした合計が合わないのです。（勿論、ｘｘｘ集計の集計文字は、
省いた後でコードを走らせています。）

数値をチェックすると合わないのは当然で、
一致する文字は１件だけの金額で他の行で、同じ名前の金額は省かれています。

エクセル２００７の集計は初めてで面倒なので、且つ一致した合計が合いませんので、

出来ましたら一致する同じデータの金額を合計してＯ列に出す方法が
あれば教えて頂けますか？
２度手間かけて本当に恐縮しています。伝え方の難しさを痛感しています。
何卒よろしくお願いします。


	【74334】Re:文字の比較

愛子

- 13/5/23(木) 18:21 -


	引用なし

	パスワード

>▼UO3 さん：
途中報告です：色々試している間に、可視セルでコピーしたデータを２種類の
コードで走らすと合計が同じ金額になりました。（先程は本当に違っていました）

しかし、可視セルのテストデータ件数は合計１３件ですが、一致したデータ件数は
３件だけです。

（２種類のコード共同じデータで同じ金額です）

よろしくお願いします。


	【74335】Re:文字の比較

UO3 - 13/5/23(木) 19:58 -


	引用なし

	パスワード

▼愛子さん：

>可視セルで張り付けたデータで一致した金額をチェックすると、これまた２種類のコードでラーンした合計が合わないのです。（勿論、ｘｘｘ集計の集計文字は、
>省いた後でコードを走らせています。）
>
>数値をチェックすると合わないのは当然で、
>一致する文字は１件だけの金額で他の行で、同じ名前の金額は省かれています。

こんばんは

【可視セル】という表現が気になっています。
私がアップしたコードは可視セルかどうかということは、全く判定していません。
オートフィルターか何かの結果でしょうか？

それと、【数値をチェックすると合わないのは当然で、】というところも気になります。
この部分、具体的に、レイアウトの特性を教えていただけますか？


	【74337】Re:文字の比較

愛子

- 13/5/23(木) 21:21 -


	引用なし

	パスワード

▼UO3 さん：
今晩は、
>こんばんは
>
>【可視セル】という表現が気になっています。
愛子：可視セルを言いましたのは、ｂシートにデータを集め集計します。
集計しました結果、各データの小計が出て総計が出ます。
各小計で出ましたデータだけを使用する為に、そのままコピーをしようとすれば隠れたデータも一緒にコピーされるので、集計時点で、目で見えるデータを
違うシートで金額を一致させる為に可視を利用しています。

その方法は、エクセル２００７でホームの右端に、検索・選択　をクリック、
条件を選択してジャンプをクリック、可視選択をクリック、コピー貼り付けを
しますと隠れたデータは無くなります。

それと、【数値をチェックすると合わないのは当然で、】というところも気に
なります。---
愛子：データの中には、同じ名前があります。一致する金額では、同じ名前の
金額が合計されていませんから（私の頭が働かなかったせいです）

金額チェックの段階で一致した金額とデータの金額を１件づつ確認して行く段階
同じ名前で複数件あり一致した金額以外にも同じ名前の金額がある事がわかった
為です。

そして最終的には、前回の質問の通り、名前が一致しました金額を合計したものを
出して下さい。例えばｂシートに　愛子が別々に３回出ます。１行目は１００、５行目は、２００、７行目は５０　であれば名前の一致した(愛子）の右、
Ｏ列に100+200+50＝３５０となるようにお願いします。


	【74340】Re:文字の比較

UO3 - 13/5/24(金) 10:17 -


	引用なし

	パスワード

▼愛子さん：

こんにちは

まず、Ｅ列に同じ名前が複数回登場するということはわかりました。
アップしたコードはユニークだという前提でしたから、そこを変更するのは容易です。
結果を記入するＯ列ですけど、
・何らかの値がはいっていて、そこにＥ，Ｌ列から『加算』する？
・Ｏ列は、いったんクリアして、Ｅ，Ｌ列の値だけから反映させる？
いずれでしょうか？
（前者は、データを直して再実行するような場合に苦労すると思いますのでやめたほうがいいですけど）

で、わからないのは、やはり『可視セル』ですね。
これは bシートにコピペしてから可視セルだけにしているのではなく、別シートでエクセル集計で小計を
生成した後、表示を小計行レベルにして（明細レベルの行は非表示にして）、その上で、可視セルを
bシートにコピペしているということですね？
そうしますと、別シートは別にして、bシートには「可視セルではないセル」は存在しないのでは？
ですから、あくまでbシートにあるものをすべて扱えばよろしいはずだと思うのですが？

>ｂシートにデータを集め集計します

ここが気になりますねぇ。bシートでこの処理をしているのですか？
そうしますと、N列に全氏名があるという、そのところがへんになりませんか？


	【74341】Re:文字の比較

UO3 - 13/5/24(金) 10:42 -


	引用なし

	パスワード

▼愛子さん：

こんにちは

あくまで想像の世界ですから、以下のコードはボツになるかもしれませんが・・・

・aシートに表があるとします。
・１行目がタイトル行で、Ｅ列が名前、Ｌ列が金額
・aシートの上で、小計機能で、グループの基準がＥ列、合計列はＬ列。
・こうした上で、表示は小計レベルに折りたたんであっても、明細レベルまですべて表示してあっても
　かまわないのですが、ここから bシートのＮ列の名前をトリガーにしてＯ列に、aシートの同名の人の
　金額を足しこむ。

こんなコードを書いてみました。

Sub Sample3()
'Dictionary処理案。
　　Dim c As Range
　　Dim newV As Variant
　　Dim i As Long
　　Dim dic As Object

　　Set dic = CreateObject("Scripting.Dictionary")

　　With Sheets("a")
　　　　'aシートの小計表から明細行を抽出して格納
　　　　For Each c In .Range("E2", .Range("E" & .Rows.Count).End(xlUp))
　　　　　　If c.EntireRow.OutlineLevel = 3 Then
　　　　　　　　dic(c.Value) = dic(c.Value) + c.EntireRow.Range("L1").Value
　　　　　　End If
　　　　Next
　　End With
　　
　　With Sheets("b")
　　　　'bシートの N列、O列の内容（２行目以降）を配列に格納
　　　　With .Range("N2", .Range("N" & .Rows.Count).End(xlUp)).Resize(, 2)
　　　　　　.Columns(2).ClearContents　 'O列をクリア
　　　　　　newV = .Value
　　　　End With
　　　　For i = 1 To UBound(newV, 1)
　　　　　　If dic.exists(newV(i, 1)) Then newV(i, 2) = dic(newV(i, 1))
　　　　Next
　　　　.Range("N2").Resize(UBound(newV, 1), UBound(newV, 2)).Value = newV
　　　　.Select
　　End With

End Sub


	【74342】Re:文字の比較

UO3 - 13/5/24(金) 11:15 -


	引用なし

	パスワード

▼愛子さん：

もし、現行の運用、aシートで集計をした上で、その可視セルのみを bシートにコピペしたうえで
bシートだけで処理するということなら、アップした Sample22 の

dic(c.Value) = c.EntireRow.Range("L1").Value

これを

dic(c.Value) = dic(c.Value) + c.EntireRow.Range("L1").Value

こうすればいいと思いますよ。


	【74343】Re:文字の比較

UO3 - 13/5/24(金) 11:20 -


	引用なし

	パスワード

▼愛子さん：

Sample3 の　

.Columns(2).ClearContents　 'O列をクリア

これは、なくしたほうがいいかもしれませんね。


	【74344】Re:文字の比較

愛子

- 13/5/24(金) 12:55 -


	引用なし

	パスワード

▼UO3 さん：
こんにちは
お世話になります。

>結果を記入するＯ列ですけど、
愛子；Ｏ列は、いったんクリアして、Ｅ，Ｌ列の値だけから反映させる方法です。

>で、わからないのは、やはり『可視セル』ですね。

>愛子； bシートにエクセル集計で小計を生成した後、表示を小計行レベルにして（明細レベルの行は非表示にして）、別シートでbシート（小計）をコピペして
から可視セルにしています。でも小計のデータと一致した合計額を出して頂ける
のですから今となっては利用しませんので---

>あくまでbシートにあるものをすべて扱えばよろしいはずだと思うのですが？
愛子；その通りです、
>
>愛子；N列に全氏名があるというのは、別シートです、

この文章を記載する前にＵＯ３様が後で書かれたコードを見ています。
そして実行しますとうまく行きました。只、要望は、小計機能はマクロに記録
するのが面倒で、出来ましたら小計機能を使わずに単なるデータで同じ名前が
あれば、同じ名前の金額を合計できる方法を教えて頂けますか？今後も利用できる
機械が多いと思いますので宜しくお願いします。


	【74345】Re:文字の比較

愛子

- 13/5/24(金) 12:57 -


	引用なし

	パスワード

▼UO3 さん：
>
>可視セルは、やめておきます。


	【74346】Re:文字の比較

愛子

- 13/5/24(金) 13:14 -


	引用なし

	パスワード

▼UO3 さん：
>こんにちは
>
あくまで想像の世界ですから、以下のコードはボツになるかもしれませんが・・・
愛子；コードをラ－ンしましたらうまく行きました、
　　　嬉しです。
　　　
　　　最後の質問です：出来ましたら、違う投稿でも記載致しましたが、
　　　　　　　　　　　最初から思いつけばよかったのですが、aシートで
　　　　　　　　　　　私が小計機能（マクロに取り組むのが面倒なので）
　　　　　　　　　　　を使わずに単なる明細だけを出す事を前提に、
　　　　　　　　　　　ｂシートのＮ列の名前をトリガ－にしてＯ列に、
　　　　　　　　　　　ａシートの同名の人の金額を足しこむように説に
　　　　　　　　　　　お願いします。後で無理を言って申し訳ないと思って
　　　　　　　　　　　います、すみません。
　　　　　　　　　　　(今後も他に利用出来来そうなので）


	【74347】Re:文字の比較

UO3 - 13/5/24(金) 13:16 -


	引用なし

	パスワード

▼愛子さん：

>この文章を記載する前にＵＯ３様が後で書かれたコードを見ています。
>そして実行しますとうまく行きました。只、要望は、小計機能はマクロに記録
>するのが面倒で、出来ましたら小計機能を使わずに単なるデータで同じ名前が
>あれば、同じ名前の金額を合計できる方法を教えて頂けますか？今後も利用できる
>機械が多いと思いますので宜しくお願いします。

２つ、コードをアップしました。
１つは Sample3 で、aシートを読んで bシートに書き込みます。
もう１つ、Sample22 の改訂連絡をしました。
これで、aシートは忘れて、あくまで bシートの内容だけで、Ｅ列同名の人の足し算になります。

この、いずれも、愛子さんのご要望を満たさなかったということですか？


	【74350】Re:文字の比較

愛子

- 13/5/24(金) 15:20 -


	引用なし

	パスワード

▼UO3 さん：
今から役員会が始まります、１時間半くらいです。
戻ってから再確認をして（私の勘違いだと思います）
お返事致しますので、お待ちください。


	【74352】Re:文字の比較

愛子

- 13/5/24(金) 18:24 -


	引用なし

	パスワード

▼UO3 さん：
下記サンプル２２をようやく見つけました。
色々チェックしていたら、解らなくなって来ました。

下記サンプル２２は同じシート内のＥ列（名前）Ｌ列（金額）Ｎ列（全員の名前）
Ｏ列(同じ名前の合計金額）で（小計機能を使わずに）１件１件のデータの集まり
を処理されるコードでしょうか？コードをラーンしましたらＬ列の金額合計と
Ｏ列の同じ名前の合計金額の総計と合いません、Ｏ列の総計がＬ列の合計に比べて
かなり少ないのです。

Sub Sample22()
'Dictionary処理案。
　　Dim c As Range
　　Dim newV As Variant
　　Dim i As Long
　　Dim dic As Object

　　Set dic = CreateObject("Scripting.Dictionary")

　　With Sheets("集計")
　　　　'bシートの名前と金額をDictionaryに格納（２行目以降）
　　　　For Each c In .Range("E2", .Range("E" & .Rows.Count).End(xlUp))
　　　　　　dic(c.Value) = c.EntireRow.Range("L1").Value
　　　　Next
　　　　'bシートの N列、O列の内容（２行目以降）を配列に格納
　　　　newV = .Range("N2", .Range("N" & .Rows.Count).End(xlUp)).Resize(, 2).Value
　　　　For i = 1 To UBound(newV, 1)
　　　　　　If dic.exists(newV(i, 1)) Then newV(i, 2) = dic(newV(i, 1))
　　　　Next
　　　　.Range("N2").Resize(UBound(newV, 1), UBound(newV, 2)).Value = newV
　　　　.Select
　　End With

End Sub

改めてのお願いですが、aシートをシート名："集計"にします　bシートを
シート名："一致"にします。シート名："集計"には,選ばれたデータが何行にも
亘ってあります。（小計機能は使いません）

シート名："一致"にはＮ列に全員の名前があり、Ｏ列にはシート名："集計"
と同じ名前の金額（同じ名前であれば合計します）が入ります。

シート名："集計"のＥ列（名前）とシート名："一致"のＮ列（名前）が合致した
ところで、シート名："一致"のＮ列の右（Ｏ列）にＥ列の同じ名前のたした金額
が表示されます様にお願いします。


	【74353】Re:文字の比較

UO3 - 13/5/24(金) 19:37 -


	引用なし

	パスワード

▼愛子さん：

13-5-24 11:15 のSample22に対する改訂連絡は試していただきましたか？
追加要件はその確認後に反映します。

>▼UO3 さん：
>下記サンプル２２をようやく見つけました。
>色々チェックしていたら、解らなくなって来ました。
>
>下記サンプル２２は同じシート内のＥ列（名前）Ｌ列（金額）Ｎ列（全員の名前）
>Ｏ列(同じ名前の合計金額）で（小計機能を使わずに）１件１件のデータの集まり
>を処理されるコードでしょうか？コードをラーンしましたらＬ列の金額合計と
>Ｏ列の同じ名前の合計金額の総計と合いません、Ｏ列の総計がＬ列の合計に比べて
>かなり少ないのです。
>
>Sub Sample22()
>'Dictionary処理案。
>　　Dim c As Range
>　　Dim newV As Variant
>　　Dim i As Long
>　　Dim dic As Object
>
>　　Set dic = CreateObject("Scripting.Dictionary")
>
>　　With Sheets("集計")
>　　　　'bシートの名前と金額をDictionaryに格納（２行目以降）
>　　　　For Each c In .Range("E2", .Range("E" & .Rows.Count).End(xlUp))
>　　　　　　dic(c.Value) = c.EntireRow.Range("L1").Value
>　　　　Next
>　　　　'bシートの N列、O列の内容（２行目以降）を配列に格納
>　　　　newV = .Range("N2", .Range("N" & .Rows.Count).End(xlUp)).Resize(, 2).Value
>　　　　For i = 1 To UBound(newV, 1)
>　　　　　　If dic.exists(newV(i, 1)) Then newV(i, 2) = dic(newV(i, 1))
>　　　　Next
>　　　　.Range("N2").Resize(UBound(newV, 1), UBound(newV, 2)).Value = newV
>　　　　.Select
>　　End With
>
>End Sub
>
>改めてのお願いですが、aシートをシート名："集計"にします　bシートを
>シート名："一致"にします。シート名："集計"には,選ばれたデータが何行にも
>亘ってあります。（小計機能は使いません）
>
>シート名："一致"にはＮ列に全員の名前があり、Ｏ列にはシート名："集計"
>と同じ名前の金額（同じ名前であれば合計します）が入ります。
>
>シート名："集計"のＥ列（名前）とシート名："一致"のＮ列（名前）が合致した
>ところで、シート名："一致"のＮ列の右（Ｏ列）にＥ列の同じ名前のたした金額
>が表示されます様にお願いします。


	【74354】Re:文字の比較

愛子

- 13/5/24(金) 20:27 -


	引用なし

	パスワード

▼UO3 さん：
今晩は、
ＵＯ３様発言：もし、現行の運用、aシートで集計をした上で、その可視セル
のみを bシートにコピペしたうえでbシートだけで処理するということなら、
アップした Sample22 のdic(c.Value) = c.EntireRow.Range("L1").Value
これをdic(c.Value) = dic(c.Value) + c.EntireRow.Range("L1").Value
こうすればいいと思いますよ。

愛子：上記変更をしましたら、うまく行きました。（同じシート上で一致した名前の金額を合計表示される）有難うございました。

上記提案を読みましたが、
ＵＯ様が上記で書かれている、「もし、現行の運用、aシートで集計をした上で、その可視セルのみを---」と書かれているその可視セルのみの所を読んで、
私はどこかに可視セルは不要ですと書きましたので、必要ないと思い実行しなかったのです、すみませんでした。私の勘違いばかりでお手間取らせてすみません
でした・

教えて頂いたコードを勉強して次に活かして
行きます。

長い時間、有難うございました。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

1454 / 13644 ﾂﾘｰ

←次へ　｜　前へ→

ページ：

┃

記事番号：

(SS)C-BOARD v3.8 is Free