Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

61667 / 76732

←次へ　｜　前へ→


	【19679】Re:教えてください

ちゃっぴ - 04/11/14(日) 11:34 -


	引用なし

	パスワード

こんな感じでいかがでしょう？
bit演算を利用した方法です。

Private strArray() As String

Sub CallGetComb()
　　Call GetComb("ABCDE")
End Sub

Sub GetComb(strTarget As String)
　　Dim lngLength As Long
　　Dim lngDefault As Long
　　Dim lngCount As Long
　　Dim lngPrim As Long
　　Dim lngElse As Long
　　Dim i As Long

　　lngLength = Len(strTarget)
　　'文字列を1文字ごとに配列に格納
　　ReDim strArray(1 To lngLength)
　　For i = 1 To lngLength
　　　　strArray(i) = Mid$(strTarget, i, 1)
　　Next i
　　
　　'組み合わせ数算出
　　lngDefault = 2 ^ (lngLength) - 1
　　lngCount = (lngDefault - 1) \ 2
　　
　　'組み合わせ取得
　　For lngPrim = 1 To lngCount
　　　　lngElse = lngDefault - lngPrim
　　　　Debug.Print strGetPattern(lngPrim) & ":" _
　　　　　　& strGetPattern(lngElse)
　　Next lngPrim
End Sub

'数値を組み合わせ文字列にする関数
Function strGetPattern(ByVal lngTarget As Long) As String
　　Dim strBuf As String
　　Dim i As Long
　　Dim j As Long
　　
　　Do
　　　　j = 2 ^ i
　　　　If lngTarget < j Then Exit Do
　　　　If lngTarget And j Then
　　　　　　strBuf = strBuf & strArray(i + 1)
　　　　End If
　　　　i = i + 1
　　Loop
　　strGetPattern = strBuf
End Function

4つ以上でも取得できると思います。

0 hits

▼

【19670】教えてください ゆか 04/11/13(土) 16:49