Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

60930 / 76732

←次へ　｜　前へ→


	【20429】Re:×ボタンを使用不可⇒使用可にしたい

[名前なし] - 04/12/9(木) 0:05 -


	引用なし

	パスワード

考え方を変えて、BeforeCloseイベントで制御するのはどうでしょうか。
以下を全てThisWorkbookモジュールに記入してください。

Option Explicit
Public CanClose As Boolean 'ブックを閉じる前にTrueに設定する

'ブックがアクティブになったとき
Private Sub Workbook_Activate()
　　Call ShowState(False)
End Sub

'ブックが非アクティブになったとき
Private Sub Workbook_Deactivate()
　　Call ShowState(True)
End Sub

'ブックを開くとき
Private Sub Workbook_Open()
　　Call ShowState(False)
　　CanClose = False
　　Application.WindowState = xlMaximized
　　ActiveWindow.Zoom = 100
End Sub

'ブックを閉じる前
Private Sub Workbook_BeforeClose(Cancel As Boolean)
　　If Not CanClose Then
　　　　MsgBox "終了ボタン以外の方法では終了できません。終了ボタンを押してください。", vbExclamation
　　End If
　　Cancel = Not CanClose
End Sub

Public Sub 終了処理()　　 '｢ブックを閉じる｣ボタン用
　　Call CloseBook
End Sub

Public Sub エクセル終了() '｢エクセル終了｣ボタン用
　　Call CloseBook(True)
End Sub

'終了前処理
Private Sub CloseBook(Optional CloseApp As Boolean = False)
　　Call ShowState(True)
　　CanClose = True
　　If CloseApp Then Application.Quit
　　ThisWorkbook.Close False
End Sub

'エクセルの状態設定
Private Sub ShowState(ParamBool As Boolean)
　　　　With ActiveWindow
　　　　　　　 .DisplayHorizontalScrollBar = ParamBool　'水平スクロールバー
　　　　　　　 .DisplayVerticalScrollBar = ParamBool　　'垂直スクロールバー
　　　　　　　 .DisplayWorkbookTabs = ParamBool　　　　 'シート見出し
　　　　　　　 .DisplayGridlines = ParamBool　　　　　　'枠線
　　　　　　　 .DisplayHeadings = ParamBool　　　　　　 '行列番号
　　　　End With
　　　　
　　　　Toolbars(1).Visible = ParamBool　　'標準ツールバー
　　　　Toolbars(2).Visible = ParamBool　　'書式ツールバー
　　　　Toolbars(5).Visible = ParamBool　　'図形ツールバー
　　　　Toolbars(7).Visible = False　　　　'フォームを消す
　　　　Toolbars(9).Visible = False　　　　'ＶＢを消す
　　　　
　　　　Application.DisplayFormulaBar = ParamBool　　　　'数式バー
　　　　Application.DisplayStatusBar = ParamBool　　　　 'ステータスバー
　　　　Application.CommandBars("Worksheet Menu Bar").Enabled = ParamBool 'ﾜｰｸｼｰﾄﾒﾆｭｰﾊﾞｰ
End Sub

2 hits

▼

【20415】×ボタンを使用不可⇒使用可にしたい AKIRA 04/12/8(水) 14:21