Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

42319 / 76735

←次へ　｜　前へ→


	【39487】Re:保存から呼び込み

Kein - 06/6/25(日) 14:53 -


	引用なし

	パスワード

どちらもアクティブシートに対しての処理です。作成・読み込みをするファイルを
仮に C:\temp\Data.txt とします。

[テキストファイルへ書き出し]

Sub Data_Exp()
　 Dim C As Range
　 Dim SAry As Variant
　 Dim Buf As String
　 Const MyF As String = "C:\temp\Data.txt"
　
　 If Dir(MyF) <> "" Then Kill MyF
　 Open MyF For Output Access Write As #1
　 For Each C In Range("A1", Range("A65536").End(xlUp))
　　　With WorksheetFunction
　　　　 SAry = .Transpose(.Transpose(C.Resize(, 4).Value))
　　　End With
　　　Buf = Join(SAry, ",")
　　　Print #1, Buf
　　　Erase SAry
　 Next
　 Close #1
End Sub

[テキストファイルから読み込み]

Sub Data_Imp()
　 Dim i As Long
　 Dim SAry As Variant
　 Dim Buf As String
　 Const MyF As String = "C:\temp\Data.txt"
　
　 If Dir(MyF) = "" Then
　　　MsgBox "開くテキストファイルが見つかりません", 48
　　　Exit Sub
　 End If
　 Open MyF For Input Access Read As #1
　 Do Until EOF(1)
　　　i = i + 1
　　　Line Input #1, Buf
　　　SAry = Split(Buf, ",")
　　　Cells(i, 1).Resize(, 4).Value = SAry
　　　Erase SAry
　 Loop
　 Close #1
End Sub

0 hits

▼

【39484】保存から呼び込み ケン 06/6/25(日) 13:36