Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

19404 / 76737

←次へ　｜　前へ→


	【62766】Re:条件分岐をＬＯＯＰで行う方法

かみちゃん - 09/8/30(日) 21:05 -


	引用なし

	パスワード

こんにちは。かみちゃん　です。

>セル：Ｇ２が、[倉庫Ａ]　か　[倉庫Ｂ]　か [倉庫Ｃ] の場合、
>セル：Ｋ２に、担当者の　[鈴木さん] を入力したいと、考えています。　　　　
>
>データ量に関係無く、セルＧ２～セルＧの最終行まで、上記の条件分岐を
>ＬＯＯＰで処理するには、どうしたらよいでしょうか？

繰り返し処理には、いろいろありますので、以下３案を示します。

'Do ～ Loopを使う方法
Sub Sample1_1()
　Dim lngRow As Long
　Dim lngRowLast As Long

　With ActiveSheet
　　lngRowLast = .Range("G" & .Rows.Count).End(xlUp).Row
　　lngRow = 2
　　Do While lngRow <= lngRowLast
　　　With .Range("G" & lngRow)
　　　　Select Case .Value
　　　　　Case Is = "倉庫Ａ", "倉庫Ｂ", "倉庫Ｃ"
　　　　　　.Offset(, 4).Value = "鈴木さん"
　　　　　Case Is = "倉庫Ｄ", "倉庫Ｅ", "倉庫Ｆ"
　　　　　　.Offset(, 4).Value = "山田さん"
　　　　　Case Is = "倉庫Ｇ", "倉庫Ｈ", "倉庫Ｉ"
　　　　　　.Offset(, 4).Value = "森さん"
　　　　End Select
　　　End With
　　　lngRow = lngRow + 1
　　Loop
　End With
　
　MsgBox "終了しました"
End Sub

'For ～ Nextを使う方法
Sub Sample1_2()
　Dim lngRow As Long
　Dim lngRowLast As Long

　With ActiveSheet
　　lngRowLast = .Range("G" & .Rows.Count).End(xlUp).Row
　　For lngRow = 2 To lngRowLast
　　　With .Range("G" & lngRow)
　　　　Select Case .Value
　　　　　Case Is = "倉庫Ａ", "倉庫Ｂ", "倉庫Ｃ"
　　　　　　.Offset(, 4).Value = "鈴木さん"
　　　　　Case Is = "倉庫Ｄ", "倉庫Ｅ", "倉庫Ｆ"
　　　　　　.Offset(, 4).Value = "山田さん"
　　　　　Case Is = "倉庫Ｇ", "倉庫Ｈ", "倉庫Ｉ"
　　　　　　.Offset(, 4).Value = "森さん"
　　　　End Select
　　　End With
　　Next
　End With
　
　MsgBox "終了しました"
End Sub

'For ～ Each ～ Nextを使う方法
Sub Sample1_3()
　Dim rngLast As Range
　Dim c As Range

　With ActiveSheet
　　Set rngLast = .Range("G" & .Rows.Count).End(xlUp)
　　For Each c In .Range("G2", rngLast)
　　　Select Case c.Value
　　　　Case Is = "倉庫Ａ", "倉庫Ｂ", "倉庫Ｃ"
　　　　　c.Offset(, 4).Value = "鈴木さん"
　　　　Case Is = "倉庫Ｄ", "倉庫Ｅ", "倉庫Ｆ"
　　　　　c.Offset(, 4).Value = "山田さん"
　　　　Case Is = "倉庫Ｇ", "倉庫Ｈ", "倉庫Ｉ"
　　　　　c.Offset(, 4).Value = "森さん"
　　　End Select
　　Next
　End With
　
　MsgBox "終了しました"
End Sub

0 hits

▼

【62765】条件分岐をＬＯＯＰで行う方法 ＡＴ 09/8/30(日) 20:47