Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

10750 / 76734

←次へ　｜　前へ→


	【71529】Re:月毎で項目別に合計したい

UO3 - 12/3/15(木) 14:06 -


	引用なし

	パスワード

▼ドカさん：

こんにちは。
以下のコードが、はたしてドガさんんが望んでおられるようなコードかどうか
はなはだ自信はありませんが・・・
ところで、アップされたサンプルデータ、一方が、全角で４月、他方が半角で4月。
このままでは、これはマッチしませんよ。

Sub Sample()
　　Dim dKey As String
　　Dim c As Range
　　Dim dic As Object
　　Dim v As Variant
　　Dim i As Long
　　Dim j As Long
　　
　　Set dic = CreateObject("Scripting.Dictionary")
　　
　　With Sheets("Sheet1")　 '元シート
　　　　For Each c In .Range("A1", .Range("A" & .Rows.Count).End(xlUp))
　　　　　　dKey = c.Value & vbTab & c.Offset(, 1).Value
　　　　　　dic(dKey) = dic(dKey) + c.Offset(, 2).Value
　　　　Next
　　End With
　　
　　With Sheets("Sheet2")　 '転記シート
　　　　v = .Range("A1").CurrentRegion.Value
　　　　For i = 2 To UBound(v, 1)
　　　　　　For j = 2 To UBound(v, 2)
　　　　　　　　dKey = v(1, j) & vbTab & v(i, 1)
　　　　　　　　v(i, j) = dic(dKey)
　　　　　　Next
　　　　Next
　　　　.Range("A1").CurrentRegion.Value = v
　　　　.Select
　　End With
　　
　　Set dic = Nothing
　　MsgBox "転記が終了しました"
　　
End Sub

8 hits

▼

【71528】月毎で項目別に合計したい ドカ 12/3/15(木) 13:08