Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

9337 / 76732

←次へ　｜　前へ→


	【72957】Re:足し算と掛け算の入った転記方法

UO3 - 12/10/17(水) 11:18 -


	引用なし

	パスワード

▼マリモさん：

こんにちは。たとえば。

Sub Sample()
　　Dim c As Range
　　Dim v() As Variant
　　Dim dkey As String
　　Dim dic As Object
　　Dim x As Long
　　
　　Set dic = CreateObject("Scripting.Dictionary")
　　
　　With Sheets("Sheet2")
　　　　For Each c In .Range("A2", .Range("A" & .Rows.Count).End(xlUp))
　　　　　　dkey = c.Value & vbTab & c.Offset(, 1).Value
　　　　　　dic(dkey) = dic.Count + 1 '1からの連番
　　　　Next
　　End With
　　
　　ReDim v(1 To dic.Count, 1 To 3)
　　
　　With Sheets("Sheet1")
　　　　For Each c In .Range("B2", .Range("B" & .Rows.Count).End(xlUp))
　　　　　　dkey = c.Value & vbTab & c.Offset(, 1).Value
　　　　　　If dic.exists(dkey) Then　　'Sheet2に記載あれば
　　　　　　　　x = dic(dkey)
　　　　　　　　v(x, 1) = v(x, 1) + c.Offset(, 2).Value '通数足しこみ
　　　　　　　　v(x, 2) = c.Offset(, 3).Value　　　　　 '単価
　　　　　　　　'金額計算をしたものを足しこみ
　　　　　　　　v(x, 3) = v(x, 3) + c.Offset(, 2).Value * c.Offset(, 3).Value
　　　　　　End If
　　　　Next
　　End With
　　
　　With Sheets("Sheet2")
　　　　.Range("C2").Resize(UBound(v, 1), UBound(v, 2)).Value = v
　　　　.Select
　　End With
　　
　　MsgBox "処理完了"
　　
End Sub

0 hits

▼

【72956】足し算と掛け算の入った転記方法 マリモ 12/10/17(水) 10:44