| |
▼よぽん さん：
事前準備の手順もすべて事細かに・・というと荷が重いですが
なんとか、できるだけわかりやすいコメントとするように努力します。
１．まず、シート上のどこかに、リストボックスに表示したい内容を、縦に入力してください。
これは別シートでも構いません。
２．で、操作するシート上で。
１）開発タブをクリックしてください。
２）開発タブにある挿入を選んでください。
３）でてきたダイアログ、下半分のActiveXコントロールからリストボックスを選んでください。
（左から４番目だと思います）
４）それを、シート上の適当な場所に貼り付けます。大きさは適当に。
５）そのリストボックスを右クリック、プロパティを選んでください。
６）プロパティウィンドウの中の ListFIllRange に １．でセットした領域をいれてください。
A1:A10 とか Sheet2!A1:A10 とか。
７）MultiSelect を 2 fmMultiSelectExtended か 1 fmMultiSelectMulti にしてください。
（これによって複数選択時の操作が異なります。詳しくは以下を参照してください）
ht p://officetanaka.net/excel/vba/tips/tips144.htm
８）Visible を False にしてください。
９）プロパティウィンドウを左上のＸボタンで閉じてください。
３．開発タブ上のデザインモードが強調表示になっていますので、これをクリックしてデザインモードを終了。
リストボックスが消えましたね。
４．シートタブを右クリックしてコードの表示を選んでください。
でてきたところ（ＶＢＥ画面、シートモジュール）に下にアップするコードを貼り付け、ＶＢＥ画面の
左上のＸボタンでＶＢＥ画面を閉じてください。
これで、任意のセルでダブルクリックすると、その右側にリストボックスが表示され、そこで選択したものが
ダブルクリックしたセル以降に転記されます。
他のセルをクリックするとリストボックスが消えます。
Option Explicit
Dim stp As Boolean
Private Sub ListBox1_Change()
Dim i As Long
Dim x As Long
Dim W As Variant
If stp Then Exit Sub
ReDim W(1 To ListBox1.ListCount)
With ListBox1
For i = 0 To .ListCount - 1
If .Selected(i) Then
x = x + 1
W(x) = .List(i)
End If
Next
If x = 0 Then Exit Sub
ReDim Preserve W(1 To x)
.TopLeftCell.Offset(, -1).Resize(x).Value = WorksheetFunction.Transpose(W)
End With
End Sub
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim i As Long
Cancel = True
stp = True
With ListBox1
.Top = Target.Top
.Left = Target.Left + Target.Width
For i = 0 To .ListCount - 1
.Selected(i) = False
Next
.Visible = True
End With
stp = False
End Sub
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
ListBox1.Visible = False
End Sub
|
|
β
- 15/4/3(金) 15:43 -
![[未読]](./data/excel/image/read_icon.gif){kind=icon}
