Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

14195 / 76734

←次へ　｜　前へ→


	【68038】Re:文字を繋げてから、縦列に並び替える

UO3 - 11/1/26(水) 20:44 -


	引用なし

	パスワード

▼ケイさん：

こんばんは

要件を誤解していたらご容赦。
途中のフラッグを判定しているところが、ちょっとベタな感じでかっこ悪いのですが。

Option Explicit

Sub Sample()
　　Dim mRow As Long
　　Dim i As Long, k As Long
　　Dim v() As String
　　Dim c As Range
　　
　　Application.ScreenUpdating = False
　　
　　i = 1
　　With Sheets("Sheet1")
　　　　mRow = WorksheetFunction.Max(.Range("A" & .Rows.Count).End(xlUp).Row, _
　　　　　　　　　　　　　　　　　　 .Range("C" & .Rows.Count).End(xlUp).Row, _
　　　　　　　　　　　　　　　　　　 .Range("E" & .Rows.Count).End(xlUp).Row)
　　　　
　　　　.Columns("G").ClearContents
　　　　.Columns("L").ClearContents
　　　　
　　　　For Each c In .Range("A1:A" & mRow)
　　　　　　k = 0
　　　　　　ReDim v(1 To 3)
　　　　　　If c.Value = 1 Then
　　　　　　　　k = k + 1
　　　　　　　　v(k) = "○○○"
　　　　　　End If
　　　　　　If c.Offset(0, 2).Value = 1 Then
　　　　　　　　k = k + 1
　　　　　　　　v(k) = "ＸＸＸ"
　　　　　　End If
　　　　　　If c.Offset(0, 4).Value = 1 Then
　　　　　　　　k = k + 1
　　　　　　　　v(k) = "△△△"
　　　　　　End If
　　　　　　If k > 0 Then
　　　　　　　　ReDim Preserve v(1 To k)
　　　　　　　　c.Offset(0, 6).Value = Join(v, ",")　'G列
　　　　　　　　.Cells(i, "L").Resize(k).Value = WorksheetFunction.Transpose(v)
　　　　　　　　i = i + k
　　　　　　End If
　　　　Next
　　End With
　　
　　Application.ScreenUpdating = True
　　
End Sub

1 hits

▼

【68028】文字を繋げてから、縦列に並び替える ケイ 11/1/26(水) 13:55