| |
こんなで出来るかも？
Listの先頭行に列見出しが有る物とします
尚、A〜C列のListをListA、D〜F列のListをListDとします
Option Explicit
Option Compare Text
Public Sub DataMatch()
'ListAのデータ列数（A列〜C列）
Const clngColumns1 As Long = 3
'ListDのデータ列数（D列〜F列）
Const clngColumns2 As Long = 3
Dim rngList1 As Range
Dim vntList1 As Variant
Dim lngRows1 As Long
Dim lngComp1 As Long
Dim vntKeys1 As Variant
Dim vntResult1 As Variant
Dim rngList2 As Range
Dim vntList2 As Variant
Dim lngRows2 As Long
Dim lngComp2 As Long
Dim vntKeys2 As Variant
Dim vntResult2 As Variant
Dim lngMatch As Long
Dim lngCount As Long
Dim strProm As String
'ListAのA1を基準とします
Set rngList1 = Worksheets("Sheet1").Cells(1, "A")
'ListDのD1を基準とする
Set rngList2 = Worksheets("Sheet1").Cells(1, "D")
'ListAの比較列の列挙(基準セル位置からの列Offsetを列挙)
'A列=0、B列=1、E列=2
vntKeys1 = Array(0, 1, 2)
'ListDの比較列の列挙(基準セル位置からの列Offsetを列挙)
'D列=0、E列=1、F列=2
vntKeys2 = Array(0, 1, 2)
'ListAの比較データを保持する配列を確保
ReDim vntList1(0 To UBound(vntKeys1))
'ListDの比較データを保持する配列を確保
ReDim vntList2(0 To UBound(vntKeys1))
'画面更新を停止
Application.ScreenUpdating = False
'ListAの基準に就いて
If Not GetBasicData(rngList1, lngRows1, _
clngColumns1, vntKeys1, vntList1, vntResult1) Then
strProm = rngList1.Parent.Name & "にデータが有りません"
GoTo Wayout
End If
'ListD基準に就いて
If Not GetBasicData(rngList2, lngRows2, _
clngColumns2, vntKeys2, vntList2, vntResult2) Then
strProm = rngList2.Parent.Name & "にデータが有りません"
GoTo Wayout
End If
'ListAの比較位置
lngComp1 = 1
'ListDの比較位置
lngComp2 = 1
'ListA若しくは、ListDが最終行に達するまで繰り返し
Do Until lngComp1 > lngRows1 And lngComp2 > lngRows2
'各列のデータを比較
lngMatch = KeyCompare(vntList1, lngComp1, vntList2, lngComp2)
'比較結果に就いて
Select Case lngMatch
Case Is = 0 'Matchiした場合
'結果用の配列の比較位置をEmptyに
vntResult1(lngComp1, 1) = Empty
vntResult2(lngComp2, 1) = Empty
'削除行数をカウント
lngCount = lngCount + 1
'ListAの比較位置を更新
lngComp1 = lngComp1 + 1
'ListDの比較位置を更新
lngComp2 = lngComp2 + 1
Case Is = -1 'ListAの固有値の場合
'ListAの比較位置を更新
lngComp1 = lngComp1 + 1
Case Is = 1 'ListDの固有値の場合
'ListDの比較位置を更新
lngComp2 = lngComp2 + 1
End Select
Loop
'ListAの順位を復帰して、行削除
'削除Flagを出力
rngList1.Offset(1, clngColumns1).Resize(lngRows1).Value = vntResult1
'ListAの順位を復帰
DataRestore rngList1, lngRows1, clngColumns1
'削除行が有るなら
If lngCount > 0 Then
'削除
With rngList1
.Offset(lngRows1 - lngCount + 1).Resize(lngCount, _
clngColumns1).Delete Shift:=xlShiftUp
End With
End If
'ListDの順位を復帰して、行削除
rngList2.Offset(1, clngColumns2).Resize(lngRows2).Value = vntResult2
DataRestore rngList2, lngRows2, clngColumns2
If lngCount > 0 Then
With rngList2
.Offset(lngRows2 - lngCount + 1).Resize(lngCount, _
clngColumns2).Delete Shift:=xlShiftUp
End With
End If
strProm = lngCount & "件の削除処理が完了しました"
Wayout:
'画面更新を再開
Application.ScreenUpdating = True
Set rngList1 = Nothing
Set rngList2 = Nothing
MsgBox strProm, vbInformation
End Sub
Private Function GetBasicData(rngList As Range, _
lngRows As Long, _
lngColumns As Long, _
vntKeys As Variant, _
vntData As Variant, _
vntResult As Variant) As Boolean
Dim i As Long
Dim lngNumb() As Long
'基準に就いて
With rngList
'行数を取得
lngRows = .Offset(Rows.Count - .Row, _
vntKeys(0)).End(xlUp).Row - .Row
'データが無ければFunctionを抜ける(戻り値=False)
If lngRows <= 0 Then
Exit Function
End If
'復帰用整列Keyを作成
ReDim lngNumb(1 To lngRows, 1 To 1)
For i = 1 To lngRows
lngNumb(i, 1) = i
Next i
'復帰用Keyの出力列を挿入
.Offset(1, lngColumns).EntireColumn.Insert
'復帰用Keyの出力
.Offset(1, lngColumns).Resize(lngRows).Value = lngNumb
'データをvntKeys1列で整列
For i = UBound(vntKeys) To 0 Step -1
DataSort .Offset(1).Resize(lngRows, _
lngColumns + 1), .Offset(1, vntKeys(i))
Next i
'比較用配列にデータを取得
For i = 0 To UBound(vntKeys)
vntData(i) = .Offset(1, vntKeys(i)) _
.Resize(lngRows + 1).Value
Next i
'復帰Keyを配列に取得
vntResult = .Offset(1, lngColumns) _
.Resize(lngRows).Value
End With
GetBasicData = True
End Function
Private Sub DataRestore(rngList As Range, _
lngRows As Long, _
lngColumns As Long)
With rngList
'元データ順位を復帰
DataSort .Offset(1).Resize(lngRows, _
lngColumns + 1), .Offset(1, lngColumns)
'復帰用Key列を削除
.Offset(1, lngColumns).EntireColumn.Delete
End With
End Sub
Private Sub DataSort(rngScope As Range, _
rngKey As Range, _
Optional lngOrientation As Long = xlTopToBottom)
rngScope.Sort _
Key1:=rngKey, Order1:=xlAscending, _
Header:=xlNo, OrderCustom:=1, MatchCase:=False, _
Orientation:=lngOrientation, SortMethod:=xlStroke
End Sub
Private Function KeyCompare(vntKeys1 As Variant, lngPos1 As Long, _
vntKeys2 As Variant, lngPos2 As Long) As Long
' データの大小比較
Dim i As Long
Dim lngMax As Long
'比較位置がDataEndを超えた場合
If lngPos1 > UBound(vntKeys1(0), 1) - 1 Then
KeyCompare = 1
Exit Function
End If
If lngPos2 > UBound(vntKeys2(0), 1) - 1 Then
KeyCompare = -1
Exit Function
End If
'1行の最大比較回数を取得(0から始まる為、回数としては+1と成る)
lngMax = UBound(vntKeys1, 1)
'1行のKeyを先頭から比較
For i = 0 To lngMax
'もし、Keyが不一致なら
If vntKeys1(i)(lngPos1, 1) <> vntKeys2(i)(lngPos2, 1) Then
'Forを抜ける
Exit For
End If
Next i
'Keyが全て一致した場合(Forが全て回り終った場合、iはlngMax+1と成る)
If i > lngMax Then
'戻り値の値として、「等しい」を返す
KeyCompare = 0
Else
'vntKeys1の値が、vntKeys2の値因り小さい場合
If vntKeys1(i)(lngPos1, 1) < vntKeys2(i)(lngPos2, 1) Then
'戻り値の値として、「小さい」を返す
KeyCompare = -1
Else
'戻り値の値として、「大きい」を返す
KeyCompare = 1
End If
End If
End Function
|
|
Hirofumi
- 08/3/20(木) 19:03 -
