Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

31509 / 76738

←次へ　｜　前へ→


	【50478】Re:コマンドバーポップアップでクリック時に処理したい

ｂｙｋｉｎ - 07/7/27(金) 0:22 -


	引用なし

	パスワード

こんばんわ。

ichinoseはんのご意見が正しいと思うねんけどな・・・
CommandBarPopupとCommandBarButtonの違い、わかってまっか？

↓こういうことやないのかな？

Sub AddCommandBar()
　　Dim MyCB As CommandBar
　　Dim MyCBP As CommandBarPopup
　　Dim MyCBC1 As CommandBarButton
　　Dim MyCBC2 As CommandBarButton

　　Set MyCB = Application.CommandBars("Cell")
　　Set MyCBP = MyCB.Controls.Add(Type:=msoControlPopup)
　　MyCBP.Caption = "Popup"
　　Set MyCBC1 = MyCBP.Controls.Add(Type:=msoControlButton)
　　MyCBC1.OnAction = "Macro1"
　　MyCBC1.Caption = "Macro1-0"
　　MyCBC1.Parameter = "0"

　　Set MyCBC2 = MyCBP.Controls.Add(Type:=msoControlButton)
　　MyCBC2.OnAction = "Macro1"
　　MyCBC2.Caption = "Macro1-1"
　　MyCBC2.Parameter = "1"

End Sub

Sub Macro1()
　　MsgBox Application.CommandBars.ActionControl.Parameter
　　'行いたい処理
End Sub

ただし、こういうときはWith使えば簡略化できまっせ。↓こんな感じ。

Sub AddCommandBar2()
　　With Application.CommandBars("Cell")
　　　　With .Controls.Add(Type:=msoControlPopup)
　　　　　　.Caption = "Popup"
　　　　　　With .Controls.Add(Type:=msoControlButton)
　　　　　　　　.OnAction = "Macro1"
　　　　　　　　.Caption = "Macro1-0"
　　　　　　　　.Parameter = "0"
　　　　　　End With
　　　　　　With .Controls.Add(Type:=msoControlButton)
　　　　　　　　.OnAction = "Macro1"
　　　　　　　　.Caption = "Macro1-1"
　　　　　　　　.Parameter = "1"
　　　　　　End With
　　　　End With
　　End With
End Sub

せやけど、実際はこのコードでは実行するたびに、メニュー項目が増えるから
ちゃんと存在チェックかけなあきまへんで。

試してみてな。
ほな。

0 hits

▼

【50475】コマンドバーポップアップでクリック時に処理したい 山形 07/7/26(木) 23:16