Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

38092 / 76738

←次へ　｜　前へ→


	【43789】Re:ｶｰｿﾙ移動で罫線を引くには

ichinose - 06/10/25(水) 19:23 -


	引用なし

	パスワード

▼かんたんさん：
こんばんは。
>または、他に罫線を引く簡単な方法があれば、あれば、教えて下さい。
コマンドバー「書式設定」に選択セル範囲に罫線を引くアイコンがあります。
これ使ったほうがよっぽど便利だと思いますけどね！！

標準モジュールに
'=======================================================
Sub main()
　　Application.StatusBar = "罫線を引きます。確定はENTERキーを押してください"
　　Application.OnKey "~", "stop_line"
　　Application.OnKey "{UP}", "up_key"
　　Application.OnKey "{DOWN}", "down_key"
　　Application.OnKey "{LEFT}", "left_key"
　　Application.OnKey "{RIGHT}", "right_key"
End Sub
'=======================================================
Sub stop_line()
　　Application.OnKey "~"
　　Application.OnKey "{UP}"
　　Application.OnKey "{DOWN}"
　　Application.OnKey "{LEFT}"
　　Application.OnKey "{RIGHT}"
　　Application.StatusBar = False
End Sub
'=======================================================
Sub up_key()
　　On Error Resume Next
　　With ActiveCell
　　　 With .Offset(-1, 0)
　　　　　.Select
　　　　　If Err.Number = 0 Then
　　　　　　 With .Borders(xlEdgeLeft)
　　　　　　　　.LineStyle = xlContinuous
　　　　　　　　.Weight = xlMedium
　　　　　　　　.ColorIndex = xlAutomatic
　　　　　　　　End With
　　　　　　 End If
　　　　　End With
　　　 End With
End Sub
'=======================================================
Sub down_key()
　　On Error Resume Next
　　With ActiveCell
　　　 With .Borders(xlEdgeLeft)
　　　　　.LineStyle = xlContinuous
　　　　　.Weight = xlMedium
　　　　　.ColorIndex = xlAutomatic
　　　　　End With
　　　 .Offset(1, 0).Select
　　　 End With
End Sub
'=======================================================
Sub left_key()
　　On Error Resume Next
　　With ActiveCell
　　　 With .Offset(0, -1)
　　　　　.Select
　　　　　If Err.Number = 0 Then
　　　　　　 With .Borders(xlEdgeTop)
　　　　　　　　.LineStyle = xlContinuous
　　　　　　　　.Weight = xlMedium
　　　　　　　　.ColorIndex = xlAutomatic
　　　　　　　　End With
　　　　　　 End If
　　　　　End With
　　　 End With
End Sub
'=======================================================
Sub right_key()
　　On Error Resume Next
　　With ActiveCell
　　　 With .Borders(xlEdgeTop)
　　　　　.LineStyle = xlContinuous
　　　　　.Weight = xlMedium
　　　　　.ColorIndex = xlAutomatic
　　　　　End With
　　　 .Offset(0, 1).Select
　　　 End With
End Sub

として、mainを実行してみてください。
実行後に↑、↓、←、→キーの移動で罫線が引かれます。
確定はEnterキーです。

0 hits

▼

【43784】ｶｰｿﾙ移動で罫線を引くには かんたん 06/10/25(水) 17:26