Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

44657 / 76732

←次へ　｜　前へ→


	【37090】Re:クリックされたコマンドボタンのセル番号

Kein - 06/4/21(金) 1:31 -


	引用なし

	パスワード

そーいう処理は、ボタンの種類を「フォームツールバー」
のものにしておくに限ります。もし現在のボタンがコントロールツールバーの
ものなら

Sub Del_BT()
　 Dim Obj As OLEObject
　
　 For Each Obj In ActiveSheet.OLEObjects
　　　If Obj.ProgId = "Forms.CommandButton.1" Then
　　　　 Obj.Delete
　　　End If
　 Next
End Sub

を１回実行して削除して下さい。そして以下のマクロを１回実行すれば、フォームの
ボタンを配置 & マクロ登録を自動的に行います。

Sub Add_BT()
　 Dim i As Integer
　 Dim Tp As Single, Wp As Single, Hp As Single

　 With Range("A1")
　　　Wp = .Width: Hp = .Height
　 End With
　 With ActiveSheet
　　　For i = 1 To 30
　　　　 Tp = .Cells(i, 1).Top
　　　　 .Buttons.Add 0, Tp, Wp, Hp
　　　Next i
　　　.Buttons.OnAction = "MyButton_Info"
　 End With
End Sub

以下のマクロは削除しないで下さい。

Sub MyButton_Info()
　 Dim x As Variant

　 x = Application.Caller
　 If VarType(x) <> 8 Then Exit Sub
　 With ActiveSheet.Buttons(x)
　　　MsgBox "インデックス = " & .Index & vbLf & _
　　　"名前 = " & .Name & vbLf & "配置した行 = " & _
　　　.TopLeftCell.Row
　 End With
End Sub

任意のボタンを押すと、そのボタンの情報をメッセージします。

10 hits

▼

【37087】クリックされたコマンドボタンの番号 monmon 06/4/21(金) 0:38