| |
▼りりす さん：
こんばんは。
>almlog.txtというファイルに、
>alm.logというファイルを結合しようとしています。
>【14950】を参考につくってみたのですが、
>
>1.”alm.log”のファイルがみつかりません、というエラーが出ます。
どの行でこのエラーが発生しますか？
> パスを指定しても同じエラーがでます。
>2.結合のプログラム文はこれでいいのでしょうか？
> なんか、違和感を感じます。
>
> Open "almlog.txt" For Append As #2
> Open "alm.log" For Input As #3
>
> i = 1
Do Until EOF(1) '気になるのはここ、EOF(3) ですよね？
> Mychar = Input(1, #3)
> Write #2, Mychar
> i = i + 1
> Loop
> Close #3
> Close #2
>
>すみませんが、よろしくお願いします。
これ両方ともテキストファイルですよね？
私がこういう処理をOpenステートメントを使って行うなら、
'===============================================================
Sub merge()
Dim fno1 As Long
Dim fno2 As Long
Dim dat1 As String
Dim myfile As Variant
Dim fdx As Long
fno1 = FreeFile()
myfile = Array("almlog.txt", "alm.log")
Open ThisWorkbook.Path & "\almlog.wrk" For Output As #fno1
For fdx = LBound(myfile) To UBound(myfile)
fno2 = FreeFile()
Open ThisWorkbook.Path & "\" & myfile(fdx) For Input As #fno2
Do Until EOF(fno2)
Line Input #fno2, dat1
Print #fno1, dat1
Loop
Close #fno2
Next fdx
Close #fno1
Kill ThisWorkbook.Path & "\" & myfile(LBound(myfile))
Name ThisWorkbook.Path & "\almlog.wrk" As ThisWorkbook.Path & "\" & myfile(LBound(myfile))
End Sub
というように Appendは使用しません。
処理中にＰＣがダウンしてもどこかで
復元が出来るようにしています。
|
|
ichinose
- 06/1/13(金) 17:40 -
