Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

61253 / 76738

←次へ　｜　前へ→


	【20108】Re:コンボコックスでシートを切り替える...

Kein - 04/11/28(日) 15:40 -


	引用なし

	パスワード

ではブックを開いたときに、標準ツールバーにコンボボックスを挿入するように
したらどうでしょーか ? 以下のマクロを全て標準モジュールに入れ、いったん
ブックを閉じて再度開いてみて下さい。

Sub Auto_Open()
　 Dim WS As Worksheet
　
　 With Application.CommandBars("Standard") _
　 .Controls.Add(Type:=msoControlComboBox, Temporary:=True)
　　　.AddItem "[シート選択]"
　　　For Each WS In Worksheets
　　　　 .AddItem WS.Name
　　　Next
　　　.Tag = "GetS"
　　　.Priority = 1
　　　.OnAction = "Ac_Sheet"
　　　.DropDownLines = 10
　　　.ListIndex = 1
　 End With
End Sub

Sub Auto_Close()
　 Dim Cmb As CommandBarControl
　
　 For Each Cmb In CommandBars("Standard").Controls
　　　If Cmb.Tag = "GetS" Then Cmb.Delete: Exit For
　 Next
　 ThisWorkbook.Save
End Sub

Sub Ac_Sheet()
　 Dim Cmb As CommandBarControl
　 Dim MyS As String
　
　 For Each Cmb In CommandBars("Standard").Controls
　　　If Cmb.Tag = "GetS" Then Exit For
　 Next
　 If Cmb Is Nothing Then Exit Sub
　 With Cmb
　　　If .ListIndex < 2 Then GoTo ELine
　　　MyS = .List(.ListIndex)
　 End With
　 With Worksheets(MyS)
　　　If .Visible = False Then .Visible = True
　　　.Activate
　 End With
　 Cmb.ListIndex = 1
ELine:
　 Set Cmb = Nothing
End Sub

0 hits

▼

【20090】コンボコックスでシートを切り替えるには... もぐすたー 04/11/27(土) 22:40