| |
Jaka さん、こうさん、おはようございます。
別解です。
インターネットエクスプローラーにURLを渡してしまう方法です。
まず、参照設定で「Microsoft Internet Controls」にチェックしてください。
クラスモジュール（Class1）に、
'==================================================
Public WithEvents ie As InternetExplorer
Public ie_opn As Boolean
Public ie_dsp_comp As Boolean
'====================================
Private Sub Class_Initialize()
Set ie = New InternetExplorer
ie.Visible = True
ie_opn = True
End Sub
'======================================================================
Private Sub ie_NavigateComplete2(ByVal pDisp As Object, URL As Variant)
ie_dsp_comp = True
End Sub
'==============================
Private Sub ie_OnQuit()
ie_dsp_comp = True
ie_opn = False
End Sub
標準モジュールに
'==============================================
Sub main()
Dim idx As Long
Dim l_url As String
Dim 今
Set iec = New Class1
With iec
idx = 0
Do While Cells(idx + 1, 1).Value <> "" And .ie_opn = True
l_url = Cells(idx + 1, 1).Hyperlinks(1).Address
.ie.Navigate l_url
.ie_dsp_comp = False
Do While .ie_dsp_comp = False
DoEvents
Loop
今 = Now()
Do While Second(Now() - 今) <= 5
DoEvents
Loop
idx = idx + 1
Loop
If .ie_opn = True Then .ie.Quit
End With
End Sub
リンクシートをアクティブにしてmainを実行してみて下さい。
尚､こうさんの「お気に入りのページ」というのが、ＩＥの「お気に入り」を
指しているなら、フォルダ「C:\WINDOWS\Favorites」を検索する方法も
あると思いますが・・・。
|
|
ichinose
- 03/8/5(火) 8:35 -
