Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

7982 / 76733

←次へ　｜　前へ→


	【74332】Re:文字の比較

UO3 - 13/5/23(木) 14:22 -


	引用なし

	パスワード

▼愛子さん：

それではシート b だけを相手にして。
アップ済みの Sample1 にあたるのが Sample11、Sample2　にあたるものが Sample22です。

Sub Sample11()
'ループでシート関数MATCHを使う基本形。処理効率は若干落ちる。
　　Dim nameV As Variant
　　Dim amtV As Variant
　　Dim newV As Variant
　　Dim i As Long
　　Dim z As Variant
　
　　With Sheets("b")
　　　　'bシートの名前列と金額列を配列に格納（２行目以降）
　　　　With .Range("E2", .Range("E" & .Rows.Count).End(xlUp))
　　　　　　nameV = .Cells.Value
　　　　　　amtV = .Offset(, 7).Value
　　　　End With
　　　　'bシートの N列、O列の内容（２行目以降）を配列に格納
　　　　newV = .Range("N2", .Range("N" & .Rows.Count).End(xlUp)).Resize(, 2).Value
　　　　For i = 1 To UBound(newV, 1)
　　　　　　z = Application.Match(newV(i, 1), nameV, 0)
　　　　　　If IsNumeric(z) Then newV(i, 2) = amtV(z, 1)
　　　　Next
　　　　.Range("N2").Resize(UBound(newV, 1), UBound(newV, 2)).Value = newV
　　　　.Select
　　End With
　
End Sub

Sub Sample22()
'Dictionary処理案。
　　Dim c As Range
　　Dim newV As Variant
　　Dim i As Long
　　Dim dic As Object
　
　　Set dic = CreateObject("Scripting.Dictionary")
　
　　With Sheets("b")
　　　　'bシートの名前と金額をDictionaryに格納（２行目以降）
　　　　For Each c In .Range("E2", .Range("E" & .Rows.Count).End(xlUp))
　　　　　　dic(c.Value) = c.EntireRow.Range("L1").Value
　　　　Next
　　　　'bシートの N列、O列の内容（２行目以降）を配列に格納
　　　　newV = .Range("N2", .Range("N" & .Rows.Count).End(xlUp)).Resize(, 2).Value
　　　　For i = 1 To UBound(newV, 1)
　　　　　　If dic.exists(newV(i, 1)) Then newV(i, 2) = dic(newV(i, 1))
　　　　Next
　　　　.Range("N2").Resize(UBound(newV, 1), UBound(newV, 2)).Value = newV
　　　　.Select
　　End With
　
End Sub

0 hits

▼

【74321】文字の比較 愛子 13/5/22(水) 17:13