Excel VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちらをご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。


	新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃過去ログ ┃ホーム

8614 / 76807

←次へ　｜　前へ→


	【73763】Re:表の比較

UO3 - 13/2/10(日) 19:51 -


	引用なし

	パスワード

▼ｔ－ｋさん：

こんばんは

>素人なのでわかりやすく教えてください

わかりやすくはないと思いますが・・・
必要なら、主要なところにコメントをつけますけど、とりあえず。

アップされたコードは全く読んでいません。
提示されたレイアウトだけを見て処理しています。

Sheet2に転記できなかったSheet1のセルに色づけするとともに、
Sheet2にしか存在しなかったものについてもSHeet2側のセルに色づけしています。

Sub Sample()
　　Dim fSh As Worksheet
　　Dim tSh As Worksheet
　　Dim fDic As Object
　　Dim tDic As Object
　　Dim c As Range
　　Dim dt As Double
　　Dim com As String
　　Dim dKey As Variant
　　
　　Application.ScreenUpdating = False
　　
　　Set fDic = CreateObject("Scripting.Dictionary")
　　Set tDic = CreateObject("Scripting.Dictionary")

　　Set fSh = Sheets("Sheet1")
　　Set tSh = Sheets("Sheet2")
　　
　　fSh.Cells.Interior.ColorIndex = xlNone
　　tSh.Cells.Interior.ColorIndex = xlNone
　　
　　With fSh.Range("A1").CurrentRegion
　　　　For Each c In .Offset(1, 2).Resize(.Rows.Count - 1, .Columns.Count - 2)
　　　　　　dt = fSh.Cells(1, c.Column).Value2
　　　　　　com = fSh.Cells(c.Row, "A").Value
　　　　　　fDic(com & dt) = VBA.Array(c.Value, c.Address(External:=True))
　　　　Next
　　End With
　　
　　With tSh.Range("A1").CurrentRegion
　　　　For Each c In .Offset(1, 2).Resize(.Rows.Count - 1, .Columns.Count - 2)
　　　　　　dt = tSh.Cells(1, c.Column).Value2
　　　　　　com = tSh.Cells(c.Row, "A").Value
　　　　　　tDic(com & dt) = VBA.Array(c.Value, c.Address(External:=True))
　　　　Next
　　End With
　　　　　　
　　'Sheet1からSheet2への転記
　　
　　For Each dKey In fDic
　　　　If tDic.exists(dKey) Then
　　　　　　Range(tDic(dKey)(1)).Value = Range(fDic(dKey)(1)).Value
　　　　Else
　　　　　　Range(fDic(dKey)(1)).Interior.ColorIndex = 3
　　　　End If
　　Next
　　
　　'Sheet2 にしか存在しない項目の色つけ
　　
　　For Each dKey In tDic
　　　　If Not fDic.exists(dKey) Then Range(tDic(dKey)(1)).Interior.ColorIndex = 3
　　Next
　　
　　tSh.Activate
　　Application.ScreenUpdating = True
　　MsgBox "転記完了"
　　
End Sub

1 hits

▼

【73761】表の比較 ｔ－ｋ 13/2/10(日) 15:38